Sign in to follow this  
Followers 0
Ontosy

double click in Listbox?

3 posts in this topic

how to catch a double click event in a Listbox with GUIGetMsg()?

Share this post


Link to post
Share on other sites



Ontosy,

I do not believe you can as there is no $GUI_EVENT_* constant for a doubleclick. So you have to intercept the $LBN_DBLCLK message sent by the ListBox like this: :)

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListBoxConstants.au3>

$hGui = GUICreate("Test", 250, 250)

$hLabel = GUICtrlCreateLabel("Selected item", 10, 180, 230, 20)
$hList = GUICtrlCreateList("Item 1", 10, 10, 230, 160);, BitOR($LBS_SORT, $LBS_NOINTEGRALHEIGHT, $LBS_NOTIFY, $WS_TABSTOP))
For $i = 2 To 6
    GUICtrlSetData($hList, "Item " & $i)
Next

GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd


Func _WM_COMMAND($hWnd, $msg, $wParam, $lParam)

    Local $nCode = BitShift($wParam, 16) ; HiWord
    Local $nIDFrom = BitAND($wParam, 0xFFFF)       ; LoWord

    Switch $nIDFrom
        Case $hList
            Switch $nCode
                Case $LBN_DBLCLK
                    $sListItem = GUICtrlRead($hList) ; Read selected item
                    GUICtrlSetData($hLabel, $sListItem) ; Display selected item
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG

EndFunc   ;==>_WM_COMMAND

All clear? :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

clear! ty :)

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0