can a listbox be set to auto scroll?

[kor 5]

expandcollapse popup

#include <GUIListBox.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>


Global $hListBox
Global $var

    Local $hGUI

    ; Create GUI
    $hGUI = GUICreate("Create Staff Progress", 400, 296)
    $hListBox = _GUICtrlListBox_Create($hGUI, "", 2, 2, 396, 296, BitOR($LBS_NOSEL, $WS_VSCROLL))
    GUISetState()

    ;MsgBox(4160, "Information", "Creating Staff")

    ; Add files
    ;_GUICtrlListBox_BeginUpdate($hListBox)
    _GUICtrlListBox_ResetContent($hListBox)
    _GUICtrlListBox_InitStorage($hListBox, 100, 4096)

    $num = 0
    Do
        $num = $num + 1
        _GUICtrlListBox_InsertString($hListBox, $num, -1)
        Sleep(100)
    Until $num > 30

    ;_GUICtrlListBox_EndUpdate($hListBox)
    
    Sleep(1200)
    $var = False

    ; Loop until user exits
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE Or $var = False

Is there a way to make this listbox auto scroll such that the newest number is always at the bottom, but you don't have to manually scroll? As the numbers populate, the listbox is automatically trying to scroll down so you always see the newest number?

I realize I can change the InsertString from a -1 to 0 to have the numbers count upward with the highest number always being at the top, but I'm not a fan of that approach.

EDIT: I'm also having a problem such that while the numbers are counting, it I attempt to close the GUI it will not close until the numbers have finished. Any idea why that is?

Edited March 23, 2011 by kor

[Melba23 2,464]

kor,

Hi again!

Is there a way to make this listbox auto scroll such that the newest number is always at the bottom

Send the list a message asking it to scroll to the end.

if I attempt to close the GUI it will not close until the numbers have finished

Because until the numbers have finished you never look for an event via GUIGetMsg - you need to check as the numbers are being inserted.

Here is an amended Do...Until loop:

Do
    $num = $num + 1
    _GUICtrlListBox_InsertString($hListBox, $num, -1)
    ; Scroll to bottom of list
    $iCount = _SendMessage($hListBox, 0x18B, 0, 0) ; $LB_GETCOUNT <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    _SendMessage($hListBox, 0x197, $iCount - 1, 0) ; $LB_SETTOPINDEX <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    Sleep(100)
    If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit ; Look for the [X] being clicked <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
Until $num > 30

Please ask if anything is unclear.

M23

[kor 5]

I can take from that code what you are doing and figure the rest out. Thank you!

[AutoBert 160]

Hi kor,

here another way to scroll do actual insertet String:

Do
        $num = $num + 1
        _GUICtrlListBox_InsertString($hListBox, $num, -1)
        _GUICtrlListBox_SetCurSel($hListBox, $num -1)
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit
        Sleep(100)
Until $num > 30

mfg autoBert

Edited March 24, 2011 by AutoBert