Sign in to follow this  
Followers 0
TheCurrent

Capture resize window event, how?

5 posts in this topic

i am trying to capture window resize event, but it doesn't work. I need it so i can resize my controls when the window is resized

see what i did

While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                MsgBox(0, "", "Dialog was closed")
                Exit
            Case $msg = $GUI_EVENT_MINIMIZE
                MsgBox(0, "", "Dialog minimized", 2)
            Case $msg = $GUI_EVENT_MAXIMIZE
                MsgBox(0, "", "Dialog restored", 2)

            Case $msg = $GUI_EVENT_RESIZED
                ConsoleWrite("Event fired " & $frmMain)

        EndSelect
    WEnd

any help why its not firing?

Share this post


Link to post
Share on other sites



TheCurrent,

It works for me: :)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 500, 500, -1, -1, BitOr($GUI_SS_DEFAULT_GUI,  $WS_SIZEBOX))

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_RESIZED
            ConsoleWrite("Resized" & @CRLF)
    EndSwitch
WEnd

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

i don't know why its not working, but i'll try it again.

is it possible to get the new width and height of the window after resize?

Share this post


Link to post
Share on other sites

TheCurrent,

If you use the GUIGetMsg loop to detect the resizing event, then you can use WinGetPos to get the new size of the GUI once the resizing is complete. You can also use a GUIRegisterMsg event handler to detect the resize and get the changing size as it occurs - if you are not too familiar with this, I recommend the GUIRegisterMsg tutorial in the Wiki. :P

This script uses both methods: :)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 500, 500, -1, -1, BitOr($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX))

GUISetState()
GUIRegisterMsg($WM_SIZE, "_WM_SIZE")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_RESIZED
            $aPos = WinGetPos($hGUI)
            ConsoleWrite("Resized to " & $aPos[2] & " - " & $aPos[3] & " <<<<<<<<<<<<" & @CRLF)

    EndSwitch

WEnd

Func _WM_SIZE($hWnd, $Msg, $wParam, $lParam)

    $iGUIWidth = BitAND($lParam, 0xFFFF)
    $iGUIHeight = BitShift($lParam, 16)
    ConsoleWrite("Resizing to " & $iGUIWidth & " - " & $iGUIHeight & @CRLF)

    Return $GUI_RUNDEFMSG

EndFunc   ;==>_WM_SIZE

And before you ask, the values are not identical as WinGetPos includes the borders and title bar whereas the return from the handler is the client area. :)

But looking back at your first post, why not use GUICtrlSetResizing to get yoru controls to resize automatically? That is what the function is there for! :D

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

thank you so much, am greatful

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0