GUI EditBox

[HeavenlyDemon]

how can i make the edit box appear enabled if it's disabled so you can copy text from it but not delete text from it

[UEZ]

how can i make the edit box appear enabled if it's disabled so you can copy text from it but not delete text from it

Either it is enabled or disabled!

However, you mean this:

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 315, 196, 192, 124)
$Edit = GUICtrlCreateEdit("", 0, 0, 313, 193, BitOR($GUI_SS_DEFAULT_EDIT,$ES_READONLY))
GUICtrlSetData(-1, "This is a text")
GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Edit
    EndSwitch
WEnd

Br,

UEZ

[HeavenlyDemon]

perfect...ty

[monoscout999]

i don´t know why but readonly never works for me.. :S same as change text color to radios checkboxes and groups... :S ¿¿are that bugs?? sorry if this is not the section, but i know few english and i don´t understand how to report these bugs...

win7 64bits.. vesion of autoit 3.3.6.1

[GEOSoft]

The help file often explains the non-bugs. If you read the page GUICtrlSetColor() you should find this

Only Button, Label, Checkbox, Group, Radio, Edit, Input, List, Listview, ListviewItem, Treeview, TreeviewItem, Graphic, Progress and Combo controls can currently be colored.

Checkbox, Radio, Group or Progress controls cannot be painted if the "Windows XP/Vista style" is used.

Button controls are always painted in "Windows Classic style".

[BrewManNH]

There is a way to recolor those on a GUI even if there is a theme selected on the computer. Here's a slightly modified example that Guiness posted The part that does the magic is in the _SetWindowTheme function. You will be able to see the difference in the the 2 checkboxes if you run the example, the first one has colored text on the check box, the other has the default text color.

#include <Array.au3>
Global $Example
Global $GUI = GUICreate("GUI")
Global $Button_Theme = GUICtrlCreateCheckbox("Theme", 10, 10, 80, 30)
_SetWindowTheme(-1)
GUICtrlSetColor(-1, "0xff0000")
GUICtrlSetBkColor(-1, "0x00FF00")
Global $Button_NoTheme = GUICtrlCreateCheckbox("NoTheme", 95, 10, 80, 30)
GUICtrlSetColor(-1, "0xff0000")
GUICtrlSetBkColor(-1, "0x00FF00")
GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $Button_Theme
            $Example = _GetWindowTheme($Button_Theme)
            _ArrayDisplay($Example, "0 = Theme & 1 = Handle") ; This is how is should be from what I can gather.
        Case $Button_NoTheme
            $Example = _GetWindowTheme($Button_NoTheme)
            _ArrayDisplay($Example, "0 = Theme & 1 = Handle") ; This is how is should be from what I can gather.
    EndSwitch
WEnd

Func _GetWindowTheme($hHandle = -1)
    Local $aReturn = DllCall("UxTheme.dll", "int", "GetWindowTheme", "hwnd", GUICtrlGetHandle($hHandle))
    If @error Then Return SetError(1, 1, 0)
    Return $aReturn
EndFunc   ;==>_GetWindowTheme

Func _SetWindowTheme($hHandle = -1) ; Taken from the Forums but available in WinAPIEx.au3 too.
    Local $aReturn = DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($hHandle), "wstr", 0, "wstr", 0)
    If @error Then Return SetError(1, 1, 0)
    Return $aReturn[0]
EndFunc   ;==>_SetWindowTheme

[monoscout999]

There is a way to recolor those on a GUI even if there is a theme selected on the computer. Here's a slightly modified example that Guiness posted The part that does the magic is in the _SetWindowTheme function. You will be able to see the difference in the the 2 checkboxes if you run the example, the first one has colored text on the check box, the other has the default text color.

Thanks a lot for the answer. This is very useful to me