StringRegExp and path

[Snoomi]

Hello, I need help on the command StringRegExp.

I should be recognized by a path...

Example:

String: Hi, C:\WINDOWS\explorer.exe -> Return: C:\WINDOWS\exploder.exe

String: C:\WINDOWS\system32\shell32.dll -> Return: C:\WINDOWS\system32\shell32.dll

String: C:\ -> Null

String: C:\WINDOWS\ -> Null

String: Hi, run C:\WINDOWS\svchost.exe -> Return: C:\WINDOWS\svchost.exe

How do I? Thanks for ur help and sorry for my English =(

[Melba23]

Snoomi,

Welcome to the AutoIt forum.

I am sure some SRE guru will come along with a one-liner in a minute, but until then this seems to work:

$sString = "Hi, C:\WINDOWS\explorer.exe" ; -> Return: C:\WINDOWS\exploder.exe
ConsoleWrite(_Extract($sString) & @CRLF)

$sString = "C:\WINDOWS\system32\shell32.dll" ; -> Return: C:\WINDOWS\system32\shell32.dll
ConsoleWrite(_Extract($sString) & @CRLF)

$sString = "C:\" ; -> Return: Null
ConsoleWrite(_Extract($sString) & @CRLF)

$sString = "C:\WINDOWS\" ; -> Return: Null
ConsoleWrite(_Extract($sString) & @CRLF)

$sString = "Hi, run C:\WINDOWS\svchost.exe" ; -> Return: C:\WINDOWS\svchost.exe
ConsoleWrite(_Extract($sString) & @CRLF)

Func _Extract($sString)

    ; Extract the file name
    $sFile = StringRegExpReplace($sString, "^.*\\", "")
    ; If no file then Null
    If $sFile = "" Then Return "Null"
    ; Look for this path
    If StringInStr($sString, "C:\WINDOWS\system32\" & $sFile) Then
        Return "C:\WINDOWS\system32\" & $sFile
    ; Or this one
    If StringInStr($sString, "C:\WINDOWS\" & $sFile) Then
        Return "C:\WINDOWS\" & $sFile
    ; And if neither were found
    Else
        Return "Null"
    EndIf

EndFunc

M23

[Snoomi]

I appreciate ur help... However, those were the only example... instead of "Hi,..." I could find any string containing a path.

There is a universal way? Thanks =)

[AdmiralAlkex]

exploder?

[Melba23]

Snoomi,

This should pull all the C:\WINDOWS\ paths from a string:

$sString = "String: Hi, C:\WINDOWS\explorer.exe -> Return: C:\WINDOWS\exploder.exe" & @CRLF & _
           "String: C:\WINDOWS\system32\shell32.dll -> Return: C:\WINDOWS\system32\shell32.dll" & @CRLF & _
           "String: C:\ -> Null" & @CRLF & _
           "String: C:\WINDOWS\ -> Null" & @CRLF & _
           "String: Hi, run C:\WINDOWS\svchost.exe -> Return: C:\WINDOWS\svchost.exe"

; get an array of all the matches
$aRet = StringRegExp($sString, "(?i)(?U)C:\\WINDOWS\\(.*)\x20", 3)

; Show the ones that match
For $i = 0 To UBound($aRet) - 1
    If $aRet[$i] Then ConsoleWrite("C:\WINDOWS\" & $aRet[$i] & @CRLF)
Next

SRE explanation:

(?i)          - Case insensitive
(?U)          - Smallest match
C:\\WINDOWS\\ - Look for C:\WINDOWS\
(.*)          - Capture the text we meet before...
\x20          - The first space

Using flag 3 we get an array of the matches which we then run through and reattach the C:\WINDOWS bit if we found a path with something after that bit.

All clear?

[Snoomi]

Is very close to what I'm looking for.

However, the path could be anything! Not only C:\ WINDOWS, also C: \Temp to say... but even just a drive, such as E:, with a file.

I find Drive + File + Extension or Drive + Directory (even more than one) + File + Extension.

To be clear... should recognize ANY type of path.

[Snoomi]

exploder?

Which script is 3 hours. My brain melted.

Yeah explorer >.<

[AdmiralAlkex]

Perhaps it's _PathSplit() you're searching for? (helpfile > File Management)

[Melba23]

Snoomi,

If you want help here it really helps if you explain what you want clearly to begin with - then we do not our waste time providing you with code which you do not want.

This code will pull all paths in a text:

#include <Array.au3>

$sString = "blah blah blah blah C:\fred\fred.ext blah blah blah blah D:\tom\dick\harry blah blah blah blah E:\ blah blah blah blah"

$aRet = StringRegExp($sString, "(?i)(?U)[[:alpha:]]:.*\x20", 3)

_ArrayDisplay($aRet)

SRE explanation:

(?i)(?U)            - As before
[[:alpha:]]:.*\x20  - Look for a letter followed by a colon and then all characters up to the next space

Is that what you want?

M23

[GEOSoft]

That's close but not accurate and I don't have time today to mess with it.

Spaces are legal in a path

"C:\freds files\fred.ext" would fail.

[Melba23]

Snoomi,

George is, as usual, correct when it comes to SREs.

See if this one is any better:

#include <Array.au3>

$sString = "blah blah blah blah C:\fred path\fred.ext blah blah blah blah D:\tom\dick\harry.dll blah blah blah blah E:\ blah blah blah blah"

$aRet = StringRegExp($sString, "(?U)[[:alpha:]]:\\.*\..*\x20" , 3)

_ArrayDisplay($aRet)

SRE:

(?U)            - Smallest match
[[:alpha:]]:\\  - Match a letter followed by :\
.*\.            - Followed by any number of characters until you find a "."
.*\x20          - Followed by any number of characters until you find a space

This should pull all paths which contain a filename with an extension, which looks like what you wanted from your first post.

But I bet George can do better when he gets round to it!

M23

[Snoomi]

Very thanks Melba23 and other. =)

[Snoomi]

If, instead of a space, there was another character such as & (for example), there is a way to stop when it finds non-alphanumeric characters? Ie when no longer az, AZ, 0-9

Sorry for my excessive demands: u were fantastic

[wakillon]

If, instead of a space, there was another character such as & (for example), there is a way to stop when it finds non-alphanumeric characters? Ie when no longer az, AZ, 0-9

Sorry for my excessive demands: u were fantastic

Try this

$_String1 =  "1mtyutu78676"
ConsoleWrite ( "Is there non-alphanumeric characters : " & _IsNoAlphanumericCharInString ( $_String1 ) & @Crlf )

$_String2 =  "1mtyut!78676"
ConsoleWrite ( "Is there non-alphanumeric characters : " & _IsNoAlphanumericCharInString ( $_String2 ) & @Crlf )

Func _IsNoAlphanumericCharInString ( $_String )
    Return StringRegExp ( $_String, "(?i)[^a-z0-9]", 0 )
EndFunc ;==> _IsNoAlphanumericCharInString ( )

[Snoomi]

You should apply here: (?U)[[:alpha:]]:\\.*\..*\x20

Let's say you should go instead of .*\x20

Because the extensions of the handles bad... must block any string other than an extension... based not only on the space...

[Melba23]

Snoomi,

This should cover what you have asked for:

#include <Array.au3>

$sString = "blah blah blah blah C:\fred path\fred.ext blah blah blah blah D:\tom\dick\harry.dtdh2?blah blah blah blah E:\ blah blah blah blah"

$aRet = StringRegExp($sString, "(?U)[[:alpha:]]:\\.*\..*(?=[^[:alnum:]])" , 3)

_ArrayDisplay($aRet)

SRE:

(?U)             - Smallest match
[[:alpha:]]:\\   - Match a letter followed by :\
.*\.             - Followed by any number of characters until you find a "."
.*               - Followed by any number of characters
(?=[^[:alnum:]]) - Until a non-alphanumeric character, which will not be included in the match

Have we finally got there?

M23

[Snoomi]

But...

String is C:\Windows\Microsoft.Net\Framework64\v3.0\WPF\PresentationFontCache.exe and return C:\Windows\Microsoft.Net !?

Fix please xD

[Melba23]

Snoomi,

What did I say earlier about moving the goalposts? ;naughty:

I will look into it later if I find the time.

M23

[Snoomi]

Snoomi,

What did I say earlier about moving the goalposts? ;naughty:

I will look into it later if I find the time.

M23

OK, thanks and sorry

[Sven]

There are filenames that don't have an extension (like C:\Windows\System32\drivers\etc\hosts), so you can't rely on just regular expressions to do the job. A regular expression would either only look for files that have an extension, or also match folder names. To catch all files, you have to also collect directory names and filter them out later.

dim $aFiles[7] = [6, "Hi, C:\WINDOWS\explorer.exe", "C:\WINDOWS\system32\shell32.dll", "C:\", "C:\WINDOWS\", "Hi, run C:\WINDOWS\svchost.exe", "hardcore sample C:\Windows\System32\drivers\etc\hosts"]
;_arraydisplay($aFiles)

for $i = 1 to $aFiles[0]
    $path_and_file = stringregexp($aFiles[$i], "[a-z A-Z]\:\\.*", 1)
    if isarray($path_and_file) Then
        $filecheck = _isfile($path_and_file[0])
        if $filecheck = 1 then
            msgbox(0, "is a file", $path_and_file[0])
        Else
            msgbox(0, "is a directory", $path_and_file[0])
        EndIf
    EndIf
Next

func _isfile($string)
    $attrib = FileGetAttrib($string)
    If StringInStr($attrib, "D") Then return(0); return 0 if directory
    return(1); otherwise return 1
EndFunc