No checkbox text color

[ineedh3lp 0]

I understand that the help file says checkbox text (labels) can be colored, but it seems not to be working...

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $msg

    GUICreate("My GUI color text")  ; will create a dialog box that when displayed is centered

    GUICtrlCreateCheckbox ("my Red checkbox text", 10, 20)
    GUICtrlSetColor(-1, 0xff0000)     ; Red

    GUISetState()

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example

Am I missing something?

[Syed23 5]

i could able to set the color for "Label","combobox" but i also fail to Check box and radio even the text color change as red for Button not for Checkbox and Radio

[Melba23 2,730]

ineedh3lp,

You need to remove the theme from the control before you can colour it:

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $msg

    GUICreate("My GUI color text")  ; will create a dialog box that when displayed is centered

    Local $hCheckbox = GUICtrlCreateCheckbox ("my Red checkbox text", 10, 20)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($hCheckbox), "wstr", 0, "wstr", 0)
    GUICtrlSetColor(-1, 0xff0000)     ; Red

    GUISetState()

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example

All clear?

M23

[ineedh3lp 0]

Excellent! Thanks Melba!