Autoit and HTA

[shazdeh]

I want to build a desktop app while using HTML, CSS and JS. Building the UI with these is really simple. Now, can I use Autoit along with HTA files for database manipulation and all the other cool stuff AI does?

[taietel]

Yes.

[shazdeh]

Thank you! How?

[taietel]

Help file is your first stop. Look at IE Management section.

[squadjot]

shazdeh did you make it work?

[BrewManNH]

The OP hasn't been online in nearly 3 years, I don't think he/she is about to answer your question.

[biase]

squadjot

i have created this with lots codes and ideas from searching on this forum, help file and webs. and i dont remember who's the owner of the ideas.

if someone found their code im using, im sorry i didnt comment your name because i already forgot.

hope this help can you and you can share any improvement or correct my mistake. Thank You

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=images\favicon.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <IE.au3>

HotKeySet("{ESC}", "On_Exit")
$oIE = ObjCreate("Shell.Explorer.2")

Global $hGUI = GUICreate("Virtual Panel", 1024, 700, -1, -1, $WS_POPUP)
Global $HPanel = GUICtrlCreateObj($oIE, 0, 0, 1024, 700)
GUICtrlSetResizing($HPanel, $GUI_DOCKAUTO)
GUISetState()

$oIE.Navigate('about:blank')
$oIE.document.body.style.border = '0px'
$oIE.document.body.style.overflow = 'hidden'

$oWin = $oIE.document.parentWindow
$oHtml = $oIE.document.getElementsByTagName('html').item(0)
Global $oHead
While Not IsObj($oHead)
    $oHead = $oIE.document.getElementsByTagName('head').item(0)
WEnd
$oBody = $oIE.document.getElementsByTagName('body').item(0)


$objScript = $oIE.document.createElement('script')
$objScript.type = 'text/javascript'
$objScript.defer = 'defer'
$objScript.text = FileRead(@ScriptDir & '\jquery.js')
$oHead.appendChild($objScript)

While Not (IsObj($oWin.jQuery))
    Sleep(100)
WEnd

$oWin.jQuery.noConflict()
Global $jq = $oWin.jQuery


$jq(StringReplace(FileRead('style.txt'), "{ScriptDir}", StringReplace(@ScriptDir, "\", "/"))).appendTo('head')
$jq(StringReplace(FileRead('body.txt'), "{ScriptDir}", StringReplace(@ScriptDir, "\", "/"))).appendTo('body')
;~ $jq('body').disableSelection()
;~ ConsoleWrite($jq('html').html() & @CRLF)

$oEvtButton1 = ObjEvent(_IEGetObjById($oIE, "button_minimize"), "evtButton_")
$oEvtButton1 = ObjEvent(_IEGetObjById($oIE, "button_close"), "evtButton_")



Func evtButton_onclick()
    Local $o_object = @COM_EventObj
    ConsoleWrite($o_object.value& @CRLF)
    Switch $o_object.value
        Case "close"
            Exit
        Case "minimize"
            GUISetState(@SW_MINIMIZE)
    EndSwitch
EndFunc

Func evtButton_($EventName)
; This is an optional event function to catch non-defined events.
; The parameter contains the name of the event being called.
    ConsoleWrite("Uncatched event: " & $EventName & @CRLF)
EndFunc


While 1
    Sleep(1000)
WEnd


Func On_Exit()
    Exit
EndFunc

Func _IEPageLoadWait($objAppIE)
    Do
        Sleep(100)
    Until ($objAppIE.readyState = 'complete' Or $objAppIE.readyState = 4)
    Do
        Sleep(100)
    Until ($objAppIE.document.readyState = 'complete' Or $objAppIE.document.readyState = 4)
EndFunc   ;==>_IEPageLoadWait

for the "jquery.js", just download it from their official web for the latest and rename the file or just download from the attached file.

EDIT:

i forgot to include the other files so i zipped all files. please download html.zip

jquery.rar

Edited August 26, 2014 by biase