How to find a word in a string

[FaridAgl 39]

<?xml version="1.0" encoding="UTF-8" ?>
<user>
<login>
  <name></name>
  <autologin>0</autologin>
  <pwd>0</pwd>
  <language>en</language>
  <skin>SkinBlack</skin>
</login>
<network tcp="0" udp="1513" used="1">
  <upnp>1</upnp>
</network>
</user>

It's my string, i want to read what is between <skin> and </skin>. in this string i should read "SkinBlack".

It's my code so far, i can find where is it but i cant read it.

$String = FileReadLine(FileOpen("user.xml"),8)
$First = StringInstr($String,"<skin>")
$Last = StringInstr($String,"</skin>")
MsgBox(0,"", "I should read from " & $First + 6 & " to " & $Last & " in line 8.")

Best Regards.

[rcmaehl 45]

Try using:

StringReplace($string, "<skin>", "")
StringReplace($string, "</skin>", "")

[FaridAgl 39]

Yes tnx, some thing like this:

$String = FileReadLine(FileOpen("user.xml"),8)
$NewString1 = StringReplace($String,"<skin>","")
$NewString2 = StringReplace($NewString1,"</skin>","")
MsgBox(0,"",$NewString2)

[Syed23 5]

you can download which will help you to do this.

i will do like this

#include "_XMLDomWrapper.au3"
$open = _XMLFileOpen(@DesktopDir & "\1.xml")
$skin = _XMLGetChildText("/user/login/skin")
MsgBox(0,"",$skin[1])

[Melba23 2,692]

D4RKON3,

Try this:

$sText = '<?xml version="1.0" encoding="UTF-8" ?>' & @CRLF & _
         '<user>'                                  & @CRLF & _
         '<login>'                                 & @CRLF & _
         '  <name></name>'                         & @CRLF & _
         '  <autologin>0</autologin>'              & @CRLF & _
         '  <pwd>0</pwd>'                          & @CRLF & _
         '  <language>en</language>'               & @CRLF & _
         '  <skin>SkinBlack</skin>'                & @CRLF & _
         '</login>'                                & @CRLF & _
         '<network tcp="0" udp="1513" used="1">'   & @CRLF & _
         '  <upnp>1</upnp>'                        & @CRLF & _
         '</network>'                              & @CRLF & _
         '</user>'

$sSkin = StringRegExpReplace($sText, "(.*\v)*(\s)*<skin>(.*)<\/skin>(\v.*)*", "$3")

MsgBox(0, "Skin", $sSkin)

Clever things SREs!

M23

[FaridAgl 39]

really tnx, i thinks it's the best way.

[madmasles 0]

$sText = '<?xml version="1.0" encoding="UTF-8" ?>' & @CRLF & _
  '<user>' & @CRLF & _
  '<login>' & @CRLF & _
  '  <name>My name</name>' & @CRLF & _
  '  <autologin>Yes</autologin>' & @CRLF & _
  '  <pwd>No</pwd>' & @CRLF & _
  '  <language>en</language>' & @CRLF & _
  '  <skin>SkinBlack</skin>' & @CRLF & _
  '</login>' & @CRLF & _
  '<network tcp="0" udp="1513" used="1">' & @CRLF & _
  '  <upnp>33</upnp>' & @CRLF & _
  '</network>' & @CRLF & _
  '</user>'
Dim $aTags[7] = [6, 'name', 'autologin', 'pwd', 'language', 'skin', 'upnp']
For $i = 1 To $aTags[0]
$sSearch = StringRegExpReplace($sText, '(?s).*?<' & $aTags[$i] & '>(.*?)</' & $aTags[$i] & '>?.*', '$1')
If @extended = 1 Then
  MsgBox(0, $aTags[$i], $sSearch)
Else
  MsgBox(16, 'Error', 'StringRegExpReplace')
EndIf
Next

Edited October 5, 2011 by madmasles

[somdcomputerguy 101]

Another way..

#include <String.au3>
$var = _StringBetween("<skin>SkinBlack</skin>", "<skin>", "</skin>")
MsgBox(0, '', $var[0])