Sign in to follow this  
Followers 0
locoforcoco9

GUI - *.txt file Communication?

2 posts in this topic

#1 ·  Posted (edited)

Is there any way I can make a GUI append text to a named file, and then later on retrieve that text?

Like, if the user types in a word, let's say "Geass", and presses a button, then the GUI will edit USERTEXT.txt to have "Geass" instead of whatever was in it, or append it to whatever was in it.

THEN, for a GUI (same, different, does it matter?) to retrieve that text later on.

Phew, any ideas?

Thanks,

~L

EDIT:

Side-question:

Can I disable a GUImenuItem? Like, have it still there, but just non-clickable?

Edited by locoforcoco9

Share this post


Link to post
Share on other sites



locoforcoco9,

Here is one very simplistic way you could do it: :)

#include <GUIConstantsEx.au3>

$sFile = "UserTxt.txt"

$hGUI_1 = GUICreate("Input", 200, 200, 100, 100)

GUICtrlCreateLabel("Enter the text here:", 10, 10, 180, 20)
$hInput = GUICtrlCreateInput("", 10, 50, 180, 20)
$hButton_1 = GUICtrlCreateButton("Save", 10, 100, 80, 30)

GUISetState()

$hGUI_2 = GUICreate("Retrieval", 200, 200, 400, 100)

GUICtrlCreateLabel("The last text saved was:", 10, 10, 180, 20)
$hLabel = GUICtrlCreateLabel("", 10, 50, 180, 20)
$hButton_2 = GUICtrlCreateButton("Retrieve", 10, 100, 80, 30)

GUISetState()

GUISwitch($hGUI_1)

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI_1
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $hButton_1
                    $hFile = FileOpen($sFile, 2)
                    FileWrite($hFile, GUICtrlRead($hInput))
                    FileClose($hFile)
                    GUICtrlSetData($hLabel, "")
            EndSwitch
        Case $hGUI_2
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $hButton_2
                    If FileExists($sFile) Then
                        GUICtrlSetData($hLabel, FileRead($sFile))
                    Else
                        GUICtrlSetData($hLabel, "Nothing saved")
                    EndIf
            EndSwitch
    EndSwitch

WEnd

You might want to read the Managing Multiple GUIs tutorial in the Wiki if you find the While...WEnd loop a bit complex. ;)

Please ask if you have any questions. :graduated:

M23

P.S. As to disabling a menuitem, look at GUICtrlSetState in the Help file. ;)


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0