One Time Pad (Vernam) - Binary Problem

[LordBlackout]

Hi,

I'm working on a File Crypter and I have a problem: I read the file in binary mode but I can't XOR the bytes with the key because they're displayed in HEX. How can I display the file's data in true binary, made of 1 and 0?

Thank you very much,

Lord_Blackout

[Matrix112]

Maybe this will help you, copied from Help File

Local $var = Binary("0x00204060")
;$var is the binary type
msgbox(0, "IsBinary", IsBinary($var))

[LordBlackout]

Yes but I need to read the file obtaining a string made of 0 and 1... in your example the variable type is "Binary", but it isn't displayed as 0 and 1..

[Matrix112]

OK, i think this post will help you:

[LordBlackout]

Thank you very much ^^

[UEZ]

Try this:

#include <Constants.au3>
Global Const $sInFile = @ScriptDir & "test.txt"
Global Const $sOutFile = @ScriptDir & "Test.crypt"

CryptFile($sInFile, $sOutFile)

MsgBox(0, "Encrypt", FileRead($sOutFile))
MsgBox(0, "Decrypt", CryptFile($sOutFile,  ""))

Func CryptFile($sInFile, $sOutFile, $XOR = 0xFF) ;coded by UEZ 2011
    Local $hFile = FileOpen($sInFile, 16)
    If $hFile = -1 Then Return SetError(1, @error, 0)
    Local $i = 0
    If Not FileSetPos($hFile, $i, $FILE_BEGIN) Then Return SetError(2, @error, 0)
    Local $crypt
    While 1
        $char = FileRead($hFile, 1)
        If @error = -1 Then ExitLoop
        $crypt &= Hex(BitXOR($char, $XOR), 2)
        $i += 1
        FileSetPos($hFile, $i, $FILE_BEGIN)
    WEnd
    FileClose($hFile)
    If $sOutFile = "" Then Return BinaryToString("0x" & $crypt)
    $hFile = FileOpen($sOutFile, 18)
    If $hFile = -1 Then Return SetError(3, @error, 0)
    FileWrite($hFile, Binary("0x" & $crypt))
    FileClose($hFile)
EndFunc

Br,

UEZ

[ProgAndy]

It is possible to use BitXOR with binary data

$XOR = 0xFFFFFFFF
$sFile = @ScriptDir & "test.txt"
$sOutFile = $sFile & ".xored"
$hFile = FileOpen($sFile, 16)
$bOutput = Binary("")
While 1

    $bRead = FileRead($hFile, 4)
    If @error Then
        ExitLoop
    ElseIf BinaryLen($bRead) < 4 Then
        $bOutput &= BinaryMid(Binary(BitXOR($bRead, $XOR)), 1, BinaryLen($bRead))
    Else
        $bOutput &= Binary(BitXOR($bRead, $XOR))
    EndIf
WEnd
FileClose($hFile)

$hFile = FileOpen($sOutFile, 18)
FileWrite($hFile, $bOutput)
FileClose($hFile)