Jump to content

disable checkbox when inputbox is empty


Recommended Posts

I have here a simple piece of my autoit script

what i wanna do is:

when my input is empty the checkbox have to be disabled.

and when he is not empty the checkbox have to be enabled.

this is my code:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 349, 184, 192, 124)
$Input1 = GUICtrlCreateInput("", 40, 24, 161, 21)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 120, 64, 89, 17)
GUISetState(@SW_SHOW)
While 1
$Msg = GUIGetMsg()
  Select
  Case $Msg = $GUI_EVENT_CLOSE
   Exit
EndSelect
WEnd

Thanks in advance

Lars

Link to post
Share on other sites
  • Moderators

lrstndm,

You can do it like this: :oops:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 349, 184, 192, 124)
$Input1 = GUICtrlCreateInput("", 40, 24, 161, 21)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 120, 64, 89, 17)
GUISetState(@SW_SHOW)
While 1
    $Msg = GUIGetMsg()
    Select
        Case $Msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect

    If GUICtrlRead($Input1) = "" And BitAnd(GUICtrlGetState($Checkbox1), $GUI_ENABLE) Then
        GUICtrlSetState($Checkbox1, $GUI_DISABLE)
    EndIf
    If GUICtrlRead($Input1) <> "" And BitAnd(GUICtrlGetState($Checkbox1), $GUI_DISABLE) Then
        GUICtrlSetState($Checkbox1, $GUI_ENABLE)
    EndIf

WEnd

You need to check whether the checkbox is enabled/disabled or you get a lot of flashing. :rip:

All clear. :D

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to post
Share on other sites

Here is modified more elegant version using WM_COMMAND and EN_CHANGE notification

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

$Form1 = GUICreate("Form1", 349, 184, 192, 124)
$Input1 = GUICtrlCreateInput("", 40, 24, 161, 21)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 120, 64, 89, 17)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUICtrlSetData($Input1, "") ; to be disabled at start

While 1
    $Msg = GUIGetMsg()
    Select
        Case $Msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

Func WM_COMMAND($hWinHandle, $iMsg, $wParam, $lParam)
    If _WinAPI_HiWord($wParam) = $EN_CHANGE And _WinAPI_LoWord($wParam) = $Input1 Then
        $data = GUICtrlRead($Input1)
        $enabled = IsEnabled($Checkbox1)

        If $data = "" And $enabled Then
            GUICtrlSetState($Checkbox1, $GUI_DISABLE)
        EndIf
        If $data <> "" And Not $enabled Then
            GUICtrlSetState($Checkbox1, $GUI_ENABLE)
        EndIf
    EndIf
EndFunc   ;==>WM_COMMAND

Func IsEnabled($control)
    Return BitAnd(GUICtrlGetState($control),$GUI_ENABLE) = $GUI_ENABLE
EndFunc
Edited by Zedna
Link to post
Share on other sites
  • Moderators

Zedna,

more elegant version

Very true - thanks for posting it. :D

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
  • Recently Browsing   0 members

    No registered users viewing this page.

×
×
  • Create New...