Default Sort for ListViewcontrol and SortStatus

[Sontec]

I have a Listviewcontrol and I use _GUICtrlListView_SortItems to sort the items therein,

however the items are only sorted when I click the column.

I have had a look at the _GUICtrlListView_SimpleSort function but found the example to difficult with al those DllStructGetData and megazillion handles.

I would like the Listview to be sort ascending on column 0 by default and

also know if a the sortstatus of the ListView is ascending or descending.

Is this possible?

[BrewManNH]

If you call the function to sort the listview, you don't need to click the column to do that, just call the function somewhere in your script after everything is put into the listview, or sort the items before you put them into your listview. If you put all of the listview items into an array first, you can use _ArraySort to sort the array, and then add the array to the LV.

[Melba23]

Sontec,

Welcome to the Autoit forum.

You can easily sort a ListView using _GUICtrlListView_SimpleSort - but you need to take care how you do it. Here is a short example:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Global $fSortDescending = False

Global $aNames[10] = ["Fred","Tom", "Dick", "Harry", "Peter", "Paul", "Mary", "Alice", "Bob", "Eve"]

$hGUI = GUICreate("Test", 500, 500)

$hListView = GUICtrlCreateListView("Names", 10, 10, 300, 300)

For $i = 0 To 9
    GUICtrlCreateListViewItem($aNames[$i], $hListView)
Next

$hButton = GUICtrlCreateButton("Sort", 10, 400, 80, 30)

$hLabel = GUICtrlCreateLabel("", 100, 405, 200, 20)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            ; Sort column 0
            _GUICtrlListView_SimpleSort($hListView, $fSortDescending, 0)
            Switch $fSortDescending
                Case True
                    GUICtrlSetData($hLabel, "Sorted Descending")
                Case Else
                    GUICtrlSetData($hLabel, "Sorted Ascending")
            EndSwitch
    EndSwitch

WEnd

The trick is the $fSortDescending variable so that the function knows which way to sort each time.

M23

[Sontec]

For now I used BrewManNH suggestion to pre-sort my array and then add it to the ViewList.

In the (near) future I am gonna try to use the SimpleSort, the example provided by Melba23 is slightly simpler and more understandable than the one in the AutoIt-helpfile ;-)

Thanks both for your help and suggestions.

Best regards,

Martijn (Sontec)