Sign in to follow this  
Followers 0
gcue

automatically resizing label based on dynamic attributes

5 posts in this topic

hello.

if the text attributes within a label change, how the label size change to reflect the new font and new font size?

i know i can use guictrlsetpos, but how can i calculate the new size of the label that will accomodate what the user picks as new font and new font size? choosefont will give me the new size but every font is different.

here's what i mean

#include <misc.au3>

$gui = GUICreate("test", 400, 200)

$label = GUICtrlCreateLabel("old", 10, 10, 20, 15)

GUISetState()

updateTXT()

While 1
    Sleep(10)
WEnd

Func updateTXT()

    MsgBox(0, "", "please choose font and a larger font size")

    $font_attributes = _ChooseFont()

    If Not @error Then
        GUICtrlSetFont($label, $font_attributes[3], "", "", $font_attributes[2])
        MsgBox(0, "", "font/size changed label size has not - how do i calculate what the new label size should be?")
        Exit
    EndIf

EndFunc   ;==>updateTXT

thanks in advance!

Share this post


Link to post
Share on other sites



Try this:

#include <GDIPlus.au3>
#include <Misc.au3>

$gui = GUICreate("test", 400, 200)

$label = GUICtrlCreateLabel("old", 10, 10, 20, 15)

GUISetState()

updateTXT()

While 1
    Sleep(10)
WEnd

Func updateTXT()

    MsgBox(0, "", "please choose font and a larger font size")

    $font_attributes = _ChooseFont()

    If Not @error Then
        $aDim = GetStringSize("old", $font_attributes[2], $font_attributes[3], $font_attributes[1])
        GUICtrlSetPos($label, 10, 10, $aDim[0], $aDim[1])
        GUICtrlSetFont($label, $font_attributes[3], "", "", $font_attributes[2], 4)
;~         MsgBox(0, "", "font/size changed label size has not - how do i calculate what the new label size should be?")
        Sleep(2000)
        Exit
    EndIf

EndFunc   ;==>updateTXT


Func GetStringSize($string, $font, $fontsize, $fontstyle)
    Local $GDIp = False
    Local $iWidth = StringLen($string) * $fontsize
    Local $iHeight = 2 * $fontsize
    If Not $ghGDIPDll Then
        _GDIPlus_Startup()
        $GDIp = True
    EndIf
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iWidth, "int", $iHeight, "int", 0, "int",  0x0026200A, "ptr", 0, "int*", 0)
    Local $hBitmap = $aResult[6]
    Local $hGrphContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    Local $hFormat = _GDIPlus_StringFormatCreate()
    Local $hFamily = _GDIPlus_FontFamilyCreate($font)
    Local $hFont = _GDIPlus_FontCreate($hFamily, $fontsize, $fontstyle)
    Local $tLayout = _GDIPlus_RectFCreate(0, 0, 0, 0)
    Local $aInfo = _GDIPlus_GraphicsMeasureString($hGrphContext, $string, $hFont, $tLayout, $hFormat)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hGrphContext)
    If $GDIp Then _GDIPlus_Shutdown()
    Local $aDim[2] = [Int(DllStructGetData($aInfo[0], "Width")), Int(DllStructGetData($aInfo[0], "Height"))]
    Return $aDim
EndFunc

Br,

UEZ


Please don't send me any personal message and ask for support! I will not reply!

Selection of finest graphical examples at Codepen.io

The own fart smells best!
Her 'sikim hıyar' diyene bir avuç tuz alıp koşma!
¯\_(ツ)_/¯  ٩(●̮̮̃•̃)۶ ٩(-̮̮̃-̃)۶ૐ

Share this post


Link to post
Share on other sites

wow thats some complex method - very nice

thank youuuuu!

U EZ the man =)

Share this post


Link to post
Share on other sites

gcue,

Or you could try the StringSize UDF in my sig. :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

very nice melba - definitely useful =)

thanks man

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0