How to read items??

[ileandros]

I am using a similar way but look what is my problem.

Here ur setting the data at the end like this

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            ; If there is a selection to delete
            If GUICtrlRead($cLabel) <> "" Then
                ; Which one is it
                $iIndex = _GUICtrlListBox_SelectString($cList, GUICtrlRead($cLabel))
                ; Delete it
                _GUICtrlListBox_DeleteString($cList, $iIndex)
                ; Clear the label
                GUICtrlSetData($cLabel, "")
            EndIf
    EndSwitch
WEnd

This is how you set the data.

GuiCtrlSetData($cLabel, "")

This is a nice way but its only use when you want to clear the entire field.

In my case i have more than 1 $cLabel added at my list and when i use it, it clears the filed and deletes everything.

I want to make it delete the spesific $cLabel that is chosen/clicked in case i have more than 1 item added and not clear everything...

Edited February 28, 2012 by ileandros

[ileandros]

I found the solution

case $BtnRemove
            $Deleteitem = GUICtrlRead($ListBoxToExecute)
            If StringStripWS($Deleteitem, 8) Then
                GUICtrlSetData($ListBoxToExecute, $Deleteitem)
                $iSel = _GUICtrlListBox_GetCurSel($ListBoxToExecute)
                _GUICtrlListBox_DeleteString($ListBoxToExecute, $iSel)
            EndIf

[ileandros]

ileandros,

You would need to use "*.log" as the mask and run it again for each separate extension.

But if you use my RecFileListToArray UDF you can search for several extensions in one pass, as BrewManNH suggested above:

$aArray = _RecFileListToArray($sPath, "*.exe;*.bat;*.au3", 1)

And the UDF will also search within subfolders if you wish.

M23

Is there a way to make ur command

$aArray = _RecFileListToArray($sPath, "*.exe;*.bat;*.au3", 1)

work with a checkbox???

I mean insteed of adding ("*.exe;*.bat;*.au3",) at the code can i make a checkbox for each of these and make the command check only these that are checked from the checkboxes??

[BrewManNH]

Yes, you can create a GUI with check boxes that you can then read to see if checked, and add the filters to the list by using a variable instead of an absolute string.

[ileandros]

Yes that is true for the checkboxes but how can i check it??

i did it like this

If  GuiCtrlRead($checkbo1) = True Then
.........

But i couldnt manage to add it at Melba23s'

[Melba23]

ileandros,

Something like this perhaps?

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $aCheck[3]

$hGUI = GUICreate("Test", 500, 500)

$aCheck[0] = GUICtrlCreateCheckbox("*.bat", 10, 10, 100, 20)
$aCheck[1] = GUICtrlCreateCheckbox("*.exe", 10, 30, 100, 20)
$aCheck[2] = GUICtrlCreateCheckbox("*.au3", 10, 50, 100, 20)

$cButton = GUICtrlCreateButton("Go", 10, 100, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $sExt_String = ""
            For $i = 0 To 2
                If GUICtrlRead($aCheck[$i]) = 1 Then
                    ; Add the type to the string wit the delimiter
                    $sExt_String &= GUICtrlRead($aCheck[$i], 1) & ";"
                EndIf
            Next
            If $sExt_String <> "" Then
                ; Remove the final ;
                $sExt_String = StringTrimRight($sExt_String, 1)
            EndIf

            MsgBox(0, "And you get....", $sExt_String)

    EndSwitch

WEnd

Then you can use that string in the _RecFileListToArray call.

M23

[ileandros]

I dont know why the heck but i dont get it.

This is how i had it working before.

Case $fileitem1
 GUICtrlSetData($ListProg, "")
 $sPath = StringReplace(@TempDir, " ", "")
 $aFiles = _RecFileListToArray($sPath, " *.* ", 1)
  For $i = 1 To $aFiles[0]
   GUICtrlSetData($ListProg, $aFiles[$i])
  Next

When i add ur script i have to empty this part right???

$aFiles = _RecFileListToArray($sPath, " EMPTY ", 1)

so the type can be chosen from the checkbox but i got error when i have it EMPTY :/

[Melba23]

ileandros,

So set a default value of *.* if no checkboxes are ticked:

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $aCheck[3]

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Select extension (Default = *.*)", 10, 10, 200, 20)

$aCheck[0] = GUICtrlCreateCheckbox("*.bat", 10, 50, 100, 20)
$aCheck[1] = GUICtrlCreateCheckbox("*.exe", 10, 70, 100, 20)
$aCheck[2] = GUICtrlCreateCheckbox("*.au3", 10, 90, 100, 20)

$cButton = GUICtrlCreateButton("Go", 10, 200, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $sExt_String = ""
            For $i = 0 To 2
                If GUICtrlRead($aCheck[$i]) = 1 Then
                    ; Add the type to the string wit the delimiter
                    $sExt_String &= GUICtrlRead($aCheck[$i], 1) & ";"
                EndIf
            Next
            If $sExt_String <> "" Then
                ; Remove the final ;
                $sExt_String = StringTrimRight($sExt_String, 1)
            Else
                ; Set default if empty
                $sExt_String = "*.*" ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            EndIf

            MsgBox(0, "And you get....", $sExt_String)

    EndSwitch

WEnd

M23

[ileandros]

puta!!!!!!!!!!!!!!

The problem is that it doesn't work. For me at least.

The problem is that when i use the @TempDir nagivate it is set to *.exe because i cant have it empty since i have an error.

and when checkbox is ticked it doesnt navigate for the checkbox only for the .exe

How can i combine mine with ur to make it damn work ???

[Melba23]

ileandros,

Perhaps like this?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <RecFileListToArray.au3>

Global $aCheck[3]

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Select extension (Default = *.*)", 10, 10, 200, 20)

$aCheck[0] = GUICtrlCreateCheckbox("*.bat", 10, 50, 100, 20)
$aCheck[1] = GUICtrlCreateCheckbox("*.exe", 10, 70, 100, 20)
$aCheck[2] = GUICtrlCreateCheckbox("*.au3", 10, 90, 100, 20)

$cButton = GUICtrlCreateButton("Go", 10, 200, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $sExt_String = ""
            For $i = 0 To 2
                If GUICtrlRead($aCheck[$i]) = 1 Then
                    ; Add the type to the string with the delimiter
                    $sExt_String &= GUICtrlRead($aCheck[$i], 1) & ";"
                EndIf
            Next
            If $sExt_String <> "" Then
                ; Remove the final ;
                $sExt_String = StringTrimRight($sExt_String, 1)
            Else
                ; Set default if empty
                $sExt_String = "*.*"
            EndIf

            ; This is what we are looking for
            MsgBox(0, "Searching for...", $sExt_String)

            $sPath = StringReplace(@TempDir, " ", "")
            $aFiles = _RecFileListToArray($sPath, $sExt_String, 1)

            ; And this is what we found
            If @error Then
                MsgBox(0, "Ooops!", "No files found in " & $sPath)
            Else
                _ArrayDisplay($aFiles, $sPath)
            EndIf

    EndSwitch

WEnd

M23

P.S. Are you actually going to write part of this script at some point in the process or am I going to do it all?

[JLogan3o13]

P.S. Are you actually going to write part of this script at some point in the process or am I going to do it all?

I do believe you qualify as a rent-a-coder after 15 answers

[ileandros]

I did a similar before but i dont know how to set it at the listbox after.

You display it with an array i want to display it at my listbox $list1 but i cant.

Thats why im getting errors im trying different ways :/

[Melba23]

ileandros,

We have discussed how to get elements from an array into a list before - and you have even posted the code yourself in your post #47 above:

$aFiles = _RecFileListToArray($sPath, " *.* ", 1)
For $i = 1 To $aFiles[0]
    GUICtrlSetData($ListProg, $aFiles[$i])
Next

M23

[ileandros]

YES!!!!!!!!!!!!!!!!!!

I made it work. It has to be like this!

Case $fileitem1
  $sExt_String = ""
            For $i = 0 To 1
                If GUICtrlRead($aCheck[$i]) = 1 Then
                    ; Add the type to the string with the delimiter
                    $sExt_String &= GUICtrlRead($aCheck[$i], 1) & ";"
                EndIf
            Next
            If $sExt_String <> "" Then
                ; Remove the final ;
                $sExt_String = StringTrimRight($sExt_String, 1)
            Else
                ; Set default if empty
                $sExt_String = "*.*"
            EndIf
            ; This is what we are looking for
            MsgBox(0, "Searching for...", $sExt_String)
            $sPath = StringReplace(@TempDir, " ", "")
            $aFiles = _RecFileListToArray($sPath, $sExt_String, 1)
   For $i = 1 To $aFiles[0]
   GUICtrlSetData($List1, $aFiles[$i])
  Next
            ; And this is what we found
            If @error Then
                MsgBox(0, "Ooops!", "No files found in " & $sPath)
EndIf

You made it work (Melba23)

Edit: i got an error. If the chosen type of files doesn't exists i dont get this that is supposed to do

If @error Then
MsgBox(0, "Ooops!", "No files found in " & $sPath)
EndIf

but i get this error message

C:Program Filesoffice.au3officeNew.au3 (107) : ==> Subscript used with non-Array variable.:
For $i = 1 To $aFiles[0]
For $i = 1 To $aFiles^ ERROR
->19:27:09 AutoIT3.exe ended.rc:1
>Exit code: 1    Time: 7.994

Edited March 1, 2012 by ileandros