[Solved] Why Isn't The ContextMenuHandler Function Called?

[Zohar 2]

Hi

I am trying to create a simple code, that will open a ContextMenu, and will give some options,

and then after I choose of MenuItem, some code will run.

Here's what I have:

#include <GuiMenu.au3>


Local $SampleArray[4] =["A","B","C","D"]

Local $WindowThatHoldsTheContextMenu = GUICreate("",1,1,-10,-10)
Local $ContextMenu   =CreateContextMenuFromArray($SampleArray,"ContextMenuHandler")
_GUICtrlMenu_TrackPopupMenu(GUICtrlGetHandle($ContextMenu),$WindowThatHoldsTheContextMenu)


Sleep(4000)



Func CreateContextMenuFromArray($MenuItems,$ContextMenuHandler_Name)
    ;Creating the Menu
Local $ContextMenu =GUICtrlCreateContextMenu()

;Creating the MenuItems
Local $ContextMenu_MenuItem

For $i=0 To UBound($MenuItems)-1
     $ContextMenu_MenuItem =GUICtrlCreateMenuItem($MenuItems[$i],$ContextMenu)
     GUICtrlSetOnEvent($ContextMenu_MenuItem,$ContextMenuHandler_Name)
Next

Return $ContextMenu
EndFunc



Func ContextMenuHandler()
Beep(1000,100)
MsgBox(0,"",@GUI_CTRLID)
EndFunc

It does show the Menu,

But after I choose a MenuItem, the relevant function is not called..

Why?

Edited September 13, 2012 by Zohar

[Melba23 2,692]

Zohar,

- 1. You have not set OnEvent mode so it is hardly suprising that nothing works.

- 2. You need to use GUISetState so that the GUI actually exists.

This works for me:

#include <GuiMenu.au3>

Opt("GUIOnEventMode", 1)

Local $SampleArray[4] = ["A", "B", "C", "D"]

Local $WindowThatHoldsTheContextMenu = GUICreate("",1,1,-10,-10)
GUISetState()
Local $ContextMenu = CreateContextMenuFromArray($SampleArray, "ContextMenuHandler")
_GUICtrlMenu_TrackPopupMenu(GUICtrlGetHandle($ContextMenu), $WindowThatHoldsTheContextMenu)

Sleep(4000)

Func CreateContextMenuFromArray($MenuItems, $ContextMenuHandler_Name)
    ;Creating the Menu
    Local $ContextMenu = GUICtrlCreateContextMenu()

    ;Creating the MenuItems
    Local $ContextMenu_MenuItem

    For $i = 0 To UBound($MenuItems) - 1
        $ContextMenu_MenuItem = GUICtrlCreateMenuItem($MenuItems[$i], $ContextMenu)
        GUICtrlSetOnEvent($ContextMenu_MenuItem, $ContextMenuHandler_Name)
    Next

    Return $ContextMenu
EndFunc   ;==>CreateContextMenuFromArray

Func ContextMenuHandler()
    Beep(1000, 100)
    MsgBox(0, "", @GUI_CtrlId)
EndFunc   ;==>ContextMenuHandler

M23

[Zohar 2]

Hi Melba

Thank you very much.

There's one problem tho, with GUISetState():

The window that I created, is hidden on purpose - I do not want to show it, and the only reason it exists, is for the ContextMenu..

(If I could create the ContextMenu without that window, I would have..)

So now when I use GUISetState(), it makes the window appear in the TaskBar..

What can I do to prevent it?

[Melba23 2,692]

Zohar,

Make the GUI a child of the hidden Autoit window like this:

Local $WindowThatHoldsTheContextMenu = GUICreate("", 1, 1, -10, -10, Default, Default, WinGetHandle(AutoItWinGetTitle()))

M23

[Zohar 2]

Hi Melba

Thank you, it worked =)

Zohar