Sign in to follow this  
Followers 0
JSands

Multiple combo boxes, mutually exclusive lists

3 posts in this topic

Let's say I have three combo boxes for selecting your three favorite colors in order, each of which contains the exact same list of colors (as in only one list is defined, and it is used to populate all three combo boxes).

When a user chooses a color from any of the three boxes, I want that option to disappear from the other two boxes. If at any time the user switches a box from one color to another, the previously removed color is added back to each box as an option, and the new option is removed from the other two boxes. What's the simplest way to go about this?

Share this post


Link to post
Share on other sites



#2 ·  Posted (edited)

JSands,

I would approach this from a different angle. I would keep the list constant but only allow the user to select a colour that was not already displayed in one of the other combos. This script shows what I mean: ;)

#include <GUIConstantsEx.au3>

; The list of colours
$sColours = "|Red|White|Blue|Green"

; The initial selections
Global $aSelection[3] = ["Red", "White", "Blue"]

$hGUI = GUICreate("Test", 500, 500)

$cCombo_1 = GUICtrlCreateCombo("", 10, 10, 200, 20)
GUICtrlSetData(-1, $sColours, "Red")
$cCombo_2 = GUICtrlCreateCombo("", 10, 40, 200, 20)
GUICtrlSetData(-1, $sColours, "White")
$cCombo_3 = GUICtrlCreateCombo("", 10, 70, 200, 20)
GUICtrlSetData(-1, $sColours, "Blue")

GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo_1, $cCombo_2, $cCombo_3
            ; Check the selection
            _Check_Selection($iMsg)
    EndSwitch

WEnd

Func _Check_Selection($iCID)

    ; What has been selected
    $sSel = GUICtrlRead($iCID)
    ; And what index of the array holds the current selection
    $iIndex = $iCID - $cCombo_1
    ; Loop through the array
    For $i = 0 To 2
        ; No pint in checking the control itself
        If $i = $iIndex Then
            ContinueLoop
        EndIf
        ; But if the selcetion matches one of the other combos
        If $sSel = $aSelection[$i] Then
            ; Reset this combo to the previosu selection
            GUICtrlSetData($iCID, $sColours, $aSelection[$iIndex])
            Return
        EndIf
    Next
    ; It is a unique selection so allow to shoe and save it in the array
    $aSelection[$iIndex] = $sSel

EndFunc

Any use? :)

M23

Edited by Melba23
Typo

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Very useful, thanks. I was approaching it with the wrong mindset, this worked well.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0