Move past a MSGBOX

[TropicalBound]

Hello,

I have created an app that connects users to my VPN (it verifies Internet connectivity, establishes the connection, adds routes to other offices, and executes the logon script). Here's the part I'm stuck at:

I would like to have a MSGBOX or similar that says "Press OK to disconnect from the VPN" while at the same time in the background, continue to ping the VPN host to verify the connection hasn't terminated. The MSGBOX would stay on the user's desktop as a reminder that they are connected and also serve to disconnect when they're ready.

I'm using While and Wend but of course, the script will not go beyond the MSGBOX until the user presses the OK button, which means the ping command is not being executed.

Does anyone have any suggestions?

Thanks!!

--TB

[Mechaflash]

gui... label... button... while loop...

[Mechaflash]

You can use this as a starting example and expand on it and change the GUI as your liking.

expandcollapse popup

#include <WindowsConstants.au3>
#include <StaticConstants.au3>

Global $sHost = "localhost", $aControl[2]
Local $iTime = 4500

$hGUI = GUICreate("", @DesktopWidth, 24, 0, @DesktopHeight - 54, $WS_POPUP, $WS_EX_TOPMOST)

$iLabelWidth = 100 + (StringLen($sHost) * 10)
$aControl[0] = GUICtrlCreateLabel("", 0, 2, $iLabelWidth, 20, BitOr($SS_SUNKEN, $SS_CENTER))
$aControl[1] = GUICtrlCreateButton("Disconnect", @DesktopWidth - 100, 2, 100, 20)
_CheckConnection()

GUISetState()

AdlibRegister("_CheckConnection", $iTime) ; You can adjust the 2nd argument based on your timeout value in the Ping() command. Default timeout is 4 seconds. Add some cushion room as well.

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $aControl[1]
            AdlibUnRegister()
            If msgbox(4 + 64 + 262144, @ScriptName, "Disconnect from your VPN?") = 6 Then
                _PerformDisconnect()
                Exit
            EndIf
            AdlibRegister("_CheckConnection", $iTime)
    EndSwitch
WEnd

Func _PerformDisconnect()
    ;Do stuff here
    AdlibUnRegister()
    msgbox(0,"","Disconnected")
EndFunc

Func _CheckConnection()
    Static Local $x = 0
    If Not $x Then
        GUICtrlSetBkColor($aControl[0], 0x7CFC00)
        GUICtrlSetData($aControl[0], "Connected to: " & $sHost)
        GUICtrlSetFont($aControl[0], 10, 600)
    EndIf
        $x+=1
    If Not Ping($sHost) Then
        AdlibUnRegister()
        msgbox(16 + 262144, @ScriptName & " - ERROR!", "You were unexpectedly disconnected from your VPN." & @LF & @LF & "Application Terminating.")
        Exit
    EndIf
EndFunc

Edited August 30, 2012 by mechaflash213

[TropicalBound]

Excellent. Thanks mechaflash. I'm not a pro in AutoIT by any means, but I follow your post pretty well. I'll give it a shot.

--TB

[Mechaflash]

Excellent. Thanks mechaflash. I'm not a pro in AutoIT by any means, but I follow your post pretty well. I'll give it a shot.

--TB

np. hope you get it to how you want it to work.

all of the admins/mvps would tell you I'm not a pro too

if there's a function you don't know how to use, you can click on the function in the code posts, or you can type the function into SciTE and press F1, to show the help file section for that function. AutoIt has the best damn documentation I've ever seen.

[Attckdog]

AutoIt has the best damn documentation I've ever seen.

Not to derail but this is exactly how I feel. I'm having a hell of a time trying to learn java simply because I am so used to AutoIt's documentation and SciTE.