Jump to content
Sign in to follow this  
Arfur9

The best way to hide text

Recommended Posts

Arfur9

Hi again..

What would the best way to hide text after a given time without causing the exe to hang ie like it does using sleep

What I'm trying to do is have a label display a message ie "You've taken a key", the message would display for 4 seconds then go away, while this is happening I need to be able to do other things

While I'm on with labels is it possible to have the background transperent?

Share this post


Link to post
Share on other sites
Melba23

Arfur9,

the message would display for 4 seconds then go away

Look at the AdlibRegister function in the Help file. This will fire a function after a given delay without halting the script:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)
GUISetBkColor(0xC4C4C4)

; Show a timer that keeps running
GUICtrlCreateLabel("The timer keep running", 10, 30, 200, 20)
$cTimer = GUICtrlCreateLabel("", 10, 50, 200, 20)

; A button to display the message
$cButton = GUICtrlCreateButton("Display", 10, 100, 80, 30)

; A label to hold the message
$cLabel = GUICtrlCreateLabel("", 200, 100, 200, 40)
GUICtrlSetFont(-1, 18)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            ; Show the message
            GUICtrlSetData($cLabel, "I show for 4 secs")
            ; Start an Adlib function to fire every 4 secs
            AdlibRegister("_Hide_text", 4000)
    EndSwitch
    ; Run the timer
    If @SEC <> GUICtrlRead($cTimer) Then
        GUICtrlSetData($cTimer, @SEC)
    EndIf
WEnd

Func _Hide_text()
    ; Remove the text
    GUICtrlSetData($cLabel, "")
    ; Cancelthe Adlib function until next time
    AdlibUnRegister("_Hide_text")
EndFunc

All clear? :)

with labels is it possible to have the background transperent?

In the Help file page for GUICtrlCreateLabel under Remarks:

To set the background to transparent, use GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT).

Always worth reading the Help file carefully before you post. ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
Arfur9

Thanks Melba23 :)

exactly what I needed, in my defence I was searching for wait, sleep etc lol

the label transparent was lazyness on my part oddly for some reason the text doesn't go away it just overlays on top of the other, but it does in the AdlibRegister example

It seems to be because my gui is set $WS_EX_COMPOSITED to prevent images flashing as they change, no biggy really I was going to have the text in a image area ui anyway..

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

×