how can i check wich value is marked in lists?

[mzgjan 0]

hi everyone

i want to check which column in my list is checked/marked

how can i do this?

[Melba23 2,837]

mzgjan,

I take it you mean a ListView - lists do not have columns.

Here is a simple example - just doubleclick an item to get the row/column data:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiListView.au3>

$hGui = GUICreate("Test", 250, 250)

$hListView = GUICtrlCreateListView("Column 1|Column 2|Column 3", 10, 10, 230, 160)
For $i = 1 To 6
    GUICtrlCreateListViewItem("Item " & $i & "1|Item " & $i & "2|Item " & $i & "3", $hListView)
Next

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd


Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $wParam

    Local $tStruct = DllStructCreate("struct;hwnd;uint_ptr;int_ptr;int;int;endstruct", $lParam)
    If @error Then Return
    Switch DllStructGetData($tStruct, 3)
        Case $NM_DBLCLK ; Look for the double click
            ConsoleWrite("Row: " & DllStructGetData($tStruct, 4) + 1 & " - Col: " &DllStructGetData($tStruct, 5) + 1 & @CRLF)
    EndSwitch

EndFunc   ;==>On_WM_NOTIFY

All clear? Please ask if not.

M23