Sign in to follow this  
Followers 0
ILLBeBack

CTRL-A does not work on Edit controls

5 posts in this topic

CTRL-A does not work on Edit controls.

Others work, such as CTRL-C, CTRL-V, CTRL-X and CTRL-Z

It's only CTRL-A that does not work.

I tried ControlClick("Testing", "", $iEdit, "right", 1)

on the edit box, then sending 'A' or 'a' afterwards, but no Joy.

Below is the sample code.

Any suggestions?

#include <GUIConstantsEx.au3>

GUICreate("Testing", 400, 240)
$iEdit = GUICtrlCreateEdit("", 10, 10, 380, 200)
$iTest1 = GUICtrlCreateButton("TEST1", 140, 215, 50, 20)
$iTest2 = GUICtrlCreateButton("TEST2", 210, 215, 50, 20)
GUISetState()

$msg = "CTRL-A does not work on Edit controls." & @CRLF & _
"Give it a try." & @CRLF & _
@CRLF & _
"Others work, such as CTRL-C, CTRL-V, CTRL-X and CTRL-Z" & @CRLF & _
"It's only CTRL-A that does not work." & @CRLF & _
@CRLF & _
'I tried ControlClick("Testing", "", $iEdit, "right", 1) ' & @CRLF & _
"on the edit box, then sending 'A' or 'a' afterwards, but no Joy." & @CRLF & _
"The TEST1 button does Right-Click-a ." & @CRLF & _
"The TEST2 button does just the Right-Click." & @CRLF & _
@CRLF & _
"Any suggestions?"
GUICtrlSetData($iEdit, $msg)

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $iTest1
ControlClick("Testing", "", $iEdit, "right", 1)
ControlSend("Testing", "", $iEdit, "a")
Case $iTest2
ControlClick("Testing", "", $iEdit, "right", 1)
EndSwitch
WEnd
Exit

Share this post


Link to post
Share on other sites



ILLBeBack,

That is a Windows problem/feature - nothing to do with AutoIt. ;)

I solve it like this:

#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <WinAPI.au3>

Global $hInput_Handle

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateEdit("here is some text", 10, 10, 480, 480)
$hInput_Handle = GUICtrlGetHandle(-1)

; Create dummy for accelerator key to activate
$cSelAll = GUICtrlCreateDummy()

GUISetState()

; Set accelerator for Ctrl+a
Dim $aAccelKeys[1][2]=[["^a", $cSelAll]]
GUISetAccelerators($aAccelKeys)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cSelAll
            _SelAll()
    EndSwitch
WEnd

Func _SelAll()
    Switch _WinAPI_GetFocus()
        Case $hInput_Handle
            _GUICtrlEdit_SetSel($hInput_Handle, 0, -1)
            Return
    EndSwitch
EndFunc   ;==>_SelAll

Please ask if you have any questions. :)

M23

1 person likes this

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

#3 ·  Posted (edited)

Instead of ControlClick, why not just assign a variable to the value of whatever is in your Edit control? Try replacing this:

Case $iTest1
ControlClick("Testing", "", $iEdit, "right", 1)
ControlSend("Testing", "", $iEdit, "a")

With this:

Case $iTest1
$var = GUICtrlRead($iEdit)
MsgBox(0, "", $var)

Edit: Too slow as always when Melba is around :)

Edited by JLogan3o13

√-1 2^3 ∑ π, and it was delicious!

Share this post


Link to post
Share on other sites

I solve it like this:

Thanks Melba23! Works very nicely.

Share this post


Link to post
Share on other sites

Instead of ControlClick, why not just assign a variable to the value of whatever is in your Edit control? Try replacing this:

Thanks JLogan3o13. I need the text to highlight for the user who presses CTRL-A. It's not that I'm trying to obtain the text for the program.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0