Sign in to follow this  
Followers 0
faustf

reduce in system tray a guy

3 posts in this topic

hi guy exist a option for gui for have a button for reduce the gui directly in systemtry ???

like first button in emule

:)

Share this post


Link to post
Share on other sites



faustf,

Perhaps like this:

#include <GUIConstantsEx.au3>

Global $fShow = True

Opt("TrayOnEventMode", 1) ; Use event trapping for tray menu
Opt("TrayMenuMode", 3) ; Default tray menu items will not be shown

$cShowHide = TrayCreateItem("Hide")
TrayItemSetOnEvent(-1, "On_ShowHide")
TrayCreateItem("")
TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, "On_Exit")

TraySetState()

$hGUI = GUICreate("Test", 500, 500, -1, -1, Default, Default, WinGetHandle(AutoItWinGetTitle()))

$cButton = GUICtrlCreateButton("To Tray", 10, 10, 80, 30)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_MINIMIZE, $cButton
            On_ShowHide()
    EndSwitch
WEnd

Func On_ShowHide()
    If $fShow Then
        GUISetState(@SW_HIDE)
        TrayItemSetText($cShowHide, "Show")
    Else
        GUISetState(@SW_SHOW)
        TrayItemSetText($cShowHide, "Hide")
    EndIf
    $fShow = Not $fShow
EndFunc

Func On_Exit()
    Exit
EndFunc

All clear? :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

yea is perfect thanks i also find other this example :)

if someone else

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0