Changing a script example to use a said Drive letter from drop down

[cnewman402]

I am requesting some guidance. I am modifying an example script located here:

I have drawn the GUI and added some directory paths. I now want to change the script to add a drop down box to select an external drive letter. Is it possible to just create a variable and place the variable from the selection into the script everywhere the C:\ is stated? If so can someone give me an example?

Thanks in advance.

[Melba23]

cnewman402,

Welcome to the AutoIt forum.

This script should show you how to do it:

expandcollapse popup

#include <GUIConstantsEx.au3>

; List available drives
$aDrives = DriveGetDrive("ALL")
; Convert the array ito a string so it can be put into the combo
$sDrives = ""
For $i = 1 To $aDrives[0]
    $sDrives &= "|" & StringUpper($aDrives[$i])
Next

; Create a GUI
$hGUI = GUICreate("Test", 500, 500)

; Create and fill the combo
$cCombo_Drives = GUICtrlCreateCombo("", 10, 10, 100, 20)
GUICtrlSetData(-1, $sDrives)

; A button to read the drive chosen
$cButton = GUICtrlCreateButton("Read", 10, 100, 80, 30)

; A label to display the final result
$cLabel = GUICtrlCreateLabel("C:\The_Path_To_Use", 10, 60, 200, 20)

GUISetState()


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            ; What does the combo read?
            $sChosen_Drive = GUICtrlRead($cCombo_Drives)
            If $sChosen_Drive <> "" Then
                ; If a drive has been chosen, reset the label path with the new drive variable
                GUICtrlSetData($cLabel, $sChosen_Drive & "\The_Path_To_Use")
            EndIf
    EndSwitch
WEnd

Please ask if you have any questions.

M23