Enable button after combo box selection

[antmar904]

i have a button disabled when the gui start but how would i enable it after selecting something from the drop down comobox?

i found this

but i am having trouble understanding it

thanks in advance

[BrewManNH]

Post the script you're having problems with and we can look at what you're doing.

[antmar904]

well i am still learning autoit and i just wanted to see how i can leverage this feature in the future.

how would i be able to enable the (Start) button when a selection is made from within the combo box?

so just for testing purposes we can use this?

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIButton.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 274, 95, 325, 276)
$Combo1 = GUICtrlCreateCombo("Combo1", 64, 8, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
$btnCancel = GUICtrlCreateButton("Cancel", 64, 40, 75, 25)
$btnStart = GUICtrlCreateButton("Start", 136, 40, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
_GUICtrlButton_Enable($btnStart, False)
Local $aTest = IniReadSection("test.ini", "test")
Local $sTest = ""
For $i = 1 To $aTest[0][0]
$sTest &= "|" & $aTest[$i][0]
GUICtrlSetData ($Combo1, $sTest)
Next
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $btnCancel
Exit
Case $btnStart
EndSwitch
WEnd

Edited March 12, 2013 by antmar904

[Melba23]

antmar904,

Just wait until something in the combo is selected and reenable the button:

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>

$Form1 = GUICreate("Form1", 274, 95, 325, 276)
$Combo1 = GUICtrlCreateCombo("Combo1", 64, 8, 145, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
$btnCancel = GUICtrlCreateButton("Cancel", 64, 40, 75, 25)
$btnStart = GUICtrlCreateButton("Start", 136, 40, 75, 25)
GUICtrlSetState(-1, $GUI_DISABLE) ; Disable button <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
GUISetState(@SW_SHOW)

; Simulate ini load
Local $aTest[3][2] = [[2, 0], ["Key One", "Value One"], ["Key Two", "Value Two"]]
Local $sTest = ""

For $i = 1 To $aTest[0][0]
    $sTest &= "|" & $aTest[$i][0]
Next
GUICtrlSetData($Combo1, $sTest)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Combo1 ; Combo fires <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            GUICtrlSetState($btnStart, $GUI_ENABLE) ; Button enabled <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        Case $btnCancel
            Exit
        Case $btnStart
    EndSwitch
WEnd

Note that it is usually easier to use native rather than UDF functions on native controls.

All clear? Please ask if not.

M23

[antmar904]

ty melba23

i do understand better now

Edited March 12, 2013 by antmar904