How do I create a GUI with dynamic labels based on an array?

[PowerCat]

I've tried to do this in the past but always failed.

I have an array of items, and I want my GUI to be created based on the content of the file, for example

I'm obviously doing it wrong, but what I'd like is for the GUI to have 1 label for each item in my array, and one button that will launch a single function, by sending the label's text as argument.

How can I have the $Label variable be created as $Label1, $Label2, etc and so on, so that I can actually use them as they won't all have the same name?

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Dim $ItemArray[5]=["this is item 1", "here is item 2", "this line contains a third one", "I don't know what's going on","ZIMBABWE"]

$AmountItems = ubound($ItemArray)-1

$Form1 = GUICreate("A Simple GUI", 400, (30*$AmountItems)+5)
$top = 0

For $i = 0 to $AmountItems
ConsoleWrite($ItemArray[$i] & @CRLF)

$Label = GUICtrlCreateLabel($ItemArray[$i], 5, $top+5)
;
; $Label & $i = GUICtrlCreateLabel($ItemArray[$i], 5, $top+5)
; sort of what I want to end up with, but I'm doing it wrong!

$top = $top + 25

Next

GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit

EndSwitch
WEnd

[FireFox]

There are many ways to do it, here is a quick one :

expandcollapse popup

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Dim $ItemArray[5] = ["this is item 1", "here is item 2", "this line contains a third one", "I don't know what's going on", "ZIMBABWE"]

$AmountItems = UBound($ItemArray) - 1

$Form1 = GUICreate("A Simple GUI", 400, (30 * $AmountItems) + 5)
$top = 0

Local $iStartId = 0, $iEndId = 0

For $i = 0 To $AmountItems
    $Label = GUICtrlCreateLabel($ItemArray[$i], 5, $top + 5)
    If $i = 0 Then $iStartId = $Label
    If $i = $AmountItems Then $iEndId = $Label
    ;
    ; $Label & $i = GUICtrlCreateLabel($ItemArray[$i], 5, $top+5)
    ; sort of what I want to end up with, but I'm doing it wrong!

    $top = $top + 25

Next

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            If $nMsg >= $iStartId And $nMsg <= $iEndId Then
                ConsoleWrite($ItemArray[$nMsg - $iStartId] & @CrLf)
            EndIf
    EndSwitch
WEnd

Br, FireFox.

Edited April 10, 2013 by FireFox

[JonBMN]

Could you do this with your GUI inside a function and have another function that dynamically generates the labels into the GUI function?

[FireFox]

Sure, give it a try If you don't manage to do it show me what you have.

[JonBMN]

expandcollapse popup

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Dim $ItemArray[5] = ["this is item 1", "here is item 2", "this line contains a third one", "I don't know what's going on", "ZIMBABWE"]

$AmountItems = UBound($ItemArray) - 1

Func Create()
Local $iStartId = 0, $iEndId = 0
For $i = 0To $AmountItems
     $Label =GUICtrlCreateLabel($ItemArray[$i], 5, $top + 5)
     If $i = 0 Then $iStartId = $Label
         If $i = $AmountItems Then $iEndId = $Label

             $Label & $i = GUICtrlCreateLabel($ItemArray[$i], 5, $top+5)

$top = $top + 25

Next
EndFunc

Func GUI()


$Form1 = GUICreate("A Simple GUI", 400, (30 * $AmountItems) + 5)
$top = 0

GUISetState(@SW_SHOW)
EndFunc


GUI()
Create()
While 1
$nMsg = GUIGetMsg()
     Switch $nMsg
         Case $GUI_EVENT_CLOSE
             Exit
         Case Else
             If $nMsg >= $iStartId And $nMsg <= $iEndId Then
                 ConsoleWrite($ItemArray[$nMsg - $iStartId] & @CrLf)
             EndIf
     EndSwitch
WEnd

Edited April 18, 2013 by JonBMN

[FireFox]

@JonBMN

It's quite simple, you need to change the scope of the variables used inside your functions to global and create the functions.

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $aItem[5] = ["this is item 1", "here is item 2", "this line contains a third one", "I don't know what's going on", "ZIMBABWE"]
Global $iAmountItems = UBound($aItem) - 1

Global $iStartId = 0, $iEndId = 0, $iTop = 0
Global $hForm1 = 0

_CreateGUI()
_CreateLabel()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            If $nMsg >= $iStartId And $nMsg <= $iEndId Then
                ConsoleWrite($aItem[$nMsg - $iStartId] & @CrLf)
            EndIf
    EndSwitch
WEnd

Func _CreateGUI()
    $hForm1 = GUICreate("A Simple GUI", 400, (30 * $iAmountItems) + 5)
EndFunc

Func _CreateLabel()
    For $i = 0 To $iAmountItems
        $Label = GUICtrlCreateLabel($aItem[$i], 5, $iTop + 5)
        If $i = 0 Then $iStartId = $Label
        If $i = $iAmountItems Then $iEndId = $Label

        $iTop = $iTop + 25
    Next

    GUISetState(@SW_SHOW, $hForm1)
EndFunc

Br, FireFox.

Edited April 18, 2013 by FireFox

[JonBMN]

Ah I see!

Thanks FireFox for the help on understanding that.

[quake101]

Sorry to jump in but I found this post very useful for a project I'm working on. With that said, I have a question. Are you able to update the data on the dynamic labels created from the array?

[BrewManNH]

GUICtrlSetData will update the label's contents.

[quake101]

GUICtrlSetData will update the label's contents.

 

I know this but how do you update the dynamic labels created from the array using the example (post #6) posted in this thread? I guess another way to ask is, do these dynamic labels have their own variable?

Edited December 23, 2013 by quake101

[BrewManNH]

If you're referring to Firefox's code, then no, his code doesn't expose the control IDs outside of the function. But if you modify the code a bit it shouldn't be hard to do that.

[quake101]

If you're referring to Firefox's code, then no, his code doesn't expose the control IDs outside of the function. But if you modify the code a bit it shouldn't be hard to do that.

 

Could you give me an example?

[BrewManNH]

Actually taking a closer look at the code, the label ids are contained in $iStartID and $iEndID. $iStartID is the control ID of the first label, and $iEndID is the control ID of the last label. So, using this information, you should be able to identify which label goes with which ID by either adding the label count to $iStartID or subtracting from $iEndID. That means that label 3's control ID would be $iStartID + 2 (+2 and not +3 because the first label is $iStartID).

[quake101]

Actually taking a closer look at the code, the label ids are contained in $iStartID and $iEndID. $iStartID is the control ID of the first label, and $iEndID is the control ID of the last label. So, using this information, you should be able to identify which label goes with which ID by either adding the label count to $iStartID or subtracting from $iEndID. That means that label 3's control ID would be $iStartID + 2 (+2 and not +3 because the first label is $iStartID).

 

Thanks!