Delete item from list by name

[Terenz]

Title say all. I have search this for a couple of days with no result.

The script:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $listview, $button, $item1, $item2, $item3, $input

    GUICreate("listview items", 220, 250, 100, 200)
    $listview = GUICtrlCreateListView("a list of names", 10, 10, 200, 150)
    $button = GUICtrlCreateButton("delete", 75, 170, 70, 20)
    $item1 = GUICtrlCreateListViewItem("dog", $listview)
    $item2 = GUICtrlCreateListViewItem("cat", $listview)
    $item3 = GUICtrlCreateListViewItem("superman", $listview)
    $input = GUICtrlCreateInput("dog", 20, 200, 150)
    GUISetState(@SW_SHOW)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $button
                $ans = MsgBox(64, "Are you sure?", "delete " & GUICtrlRead($input) & " item?")
;~              If $ans = 1 Then do something
        EndSwitch
    WEnd
EndFunc   ;==>Example

So it's possible to delete an item of a listview only using the name? Thanks

[PhoenixXL]

Check it

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Example()

Func Example()
    Local $listview, $button, $item1, $item2, $item3, $input

    GUICreate("listview items", 220, 250, 100, 200)
    $listview = GUICtrlCreateListView("a list of names", 10, 10, 200, 150)
    $button = GUICtrlCreateButton("delete", 75, 170, 70, 20)
    $item1 = GUICtrlCreateListViewItem("dog", $listview)
    $item2 = GUICtrlCreateListViewItem("cat", $listview)
    $item3 = GUICtrlCreateListViewItem("superman", $listview)
    $input = GUICtrlCreateInput("dog", 20, 200, 150)
    GUISetState(@SW_SHOW)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $button
                $ans = MsgBox(64, "Are you sure?", "delete " & GUICtrlRead($input) & " item?")
                If $ans = 1 Then DeleteItemByName(GUICtrlRead($input), GUICtrlGetHandle($listview))
        EndSwitch
    WEnd
EndFunc   ;==>Example

Func DeleteItemByName($s_Text, $hListView)

    $iItem = _GUICtrlListView_FindText($hListView, $s_Text, -1, False, False)
    If $iItem < 0 Then Return 0

    _GUICtrlListView_DeleteItem($hListView, $iItem)

EndFunc   ;==>DeleteItemByName

[Terenz]

Perfect, thank you