How I can get ComboBox key Value ?

[mohammadezazi]

Hi

This is my code.

I want to get the key value from .ini file.

Thanks for help.

And the ini file is:

[Combo]
1=combotext1
2=combotext2
3=combotext3
4=combotext4
5=combotext5
 

for example : I want to get the number 3 , when i select the combobox3 text in combobox.

#include <Constants.au3>
#include <GuiComboBox.au3>
#include <ComboConstants.au3>

Global $ini_saved_file = @ScriptDir & "\config.ini"
Global $hCombo

;-------------------------------------------------------------------------------------------------------------Create GUI
$hgui = GUICreate("MyTest", 400, 296)
;------------------------------------------------------------------------------------------create ComboBox
$cCombo = GUICtrlCreateCombo('', 2, 180, 396, 296)

_ReadComboOptions_FromINI()
;-------------------------------------------------------------------------------------------------------------------------------------------------------------
GUISetState()   
While 1
    $msg = GUIGetMsg()
    Switch $msg               
                  Case $GUI_EVENT_CLOSE
                            GUIDelete($hgui)
                  Exit
   EndSwitch
WEnd

Func _ReadComboOptions_FromINI()
    $aIniRead = IniReadSection($ini_saved_file, "Combo")
    If Not @Error Then
        $sCombo_List = ""       
        For $i = 1 To $aIniRead[0][0]
            $sCombo_List &= "|" & $aIniRead[$i][1]          
        Next
        GUICtrlSetData($cCombo, $sCombo_List)
     EndIf   
  EndFunc

Edited July 1, 2013 by mohammadezazi

[Melba23]

mohammadezazi,

You already have the ini array, so use it:

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $ini_saved_file = @ScriptDir & "\config.ini"
Global $aIniRead = IniReadSection($ini_saved_file, "Combo")
If @error Then
    MsgBox(0,"Ooops", "Error")
    Exit
EndIf

$hGUI = GUICreate("MyTest", 400, 296)

$cCombo = GUICtrlCreateCombo('', 2, 180, 396, 296)

_ReadComboOptions_FromINI()

GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            GUIDelete($hGUI)
            Exit
        Case $cCombo
            For $i = 1 To $aIniRead[0][0]
                If $aIniRead[$i][1] == GUICtrlRead($cCombo) Then
                    MsgBox(0, "Hi", $i)
                    ExitLoop
                EndIf
            Next
    EndSwitch
WEnd

Func _ReadComboOptions_FromINI()
    $sCombo_List = ""
    For $i = 1 To $aIniRead[0][0]
        $sCombo_List &= "|" & $aIniRead[$i][1]
    Next
    GUICtrlSetData($cCombo, $sCombo_List)
EndFunc   ;==>_ReadComboOptions_FromINI

All clear?

M23

[mohammadezazi]

Tnx

I love you

It works fine

Edited July 1, 2013 by mohammadezazi