Blinking listview items

[ajit]

Hi,

I want to create a list view that would have some blinking items so as to grab the attention of the user.   I would be grateful for any ideas, links or examples.   Example of trigger for the blinking could be system time matching with list view item.  

Regards,

Ajit

[orbs]

not tested: how about GUICtrlSetColor() for the ListViewItem you want to emphasize?

Edited July 3, 2013 by orbs

[DW1]

If you want this to blink without interrupting the rest of the script you could set up a system to keep track of what should be blinking so that you can just add an item to the array if you want it to blink, then have a function that runs every X milliseconds from AdlibRegister to process any work to do in the array.  If that didn't make sense, here is a quick example of what I mean (This way you just have to call blink() to add an item to the array that is watched by our AdlibRegistered function).

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Array.au3>
Global $aBlink[1][5] = [[0]]
AdlibRegister('Blinker')

$hGUI = GUICreate("LV blink", 220, 240)
$hLV = GUICtrlCreateListView("col1  |col2|col3  ", 10, 10, 200, 150)
$item1 = GUICtrlCreateListViewItem("item2|col22|col23", $hLV)
$item2 = GUICtrlCreateListViewItem("item1|col12|col13", $hLV)
$item3 = GUICtrlCreateListViewItem("item3|col32|col33", $hLV)
$hButton1 = GUICtrlCreateButton("Blink item1", 10, 165, 200, 20)
$hButton2 = GUICtrlCreateButton("Blink item2", 10, 190, 200, 20)
$hButton3 = GUICtrlCreateButton("Blink item3", 10, 215, 200, 20)

GUICtrlSetColor($item1, 0x000000)

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton1
            Blink($item1)
        Case $hButton2
            Blink($item2)
        Case $hButton3
            Blink($item3)

    EndSwitch
WEnd

;Blink(Item handle, color to blink to, color to return to, how many times)
Func Blink($hItem, $iColorB = 0xFF0000, $iColorR = 0x000000, $iTimes = 8)
    $aBlink[0][0] += 1
    ReDim $aBlink[UBound($aBlink) + 1][5]
    $aBlink[UBound($aBlink) -1][0] = $hItem
    $aBlink[UBound($aBlink) -1][1] = $iColorB
    $aBlink[UBound($aBlink) -1][2] = $iColorR
    $aBlink[UBound($aBlink) -1][3] = $iTimes
    $aBlink[UBound($aBlink) -1][4] = 0
EndFunc

Func Blinker()
    If $aBlink[0][0] = 0 Then Return
    For $i = 1 To $aBlink[0][0]
        If $aBlink[$i][4] = 0 Then
            GUICtrlSetColor($aBlink[$i][0], $aBlink[$i][1])
            $aBlink[$i][4] = 1
        Else
            GUICtrlSetColor($aBlink[$i][0], $aBlink[$i][2])
            $aBlink[$i][3] -= 1
            $aBlink[$i][4] = 0
        EndIf
    Next
    ;Remove entries that are done
    For $i = $aBlink[0][0] To 1 Step -1
        If $aBlink[$i][3] = 0 Then
            _ArrayDelete($aBlink, $i)
            $aBlink[0][0] -= 1
        EndIf
    Next
EndFunc

Edited July 3, 2013 by danwilli

[ajit]

@danwilli,

Thanks, that looks beautiful when blinking.

Thanks again,

Regards,

Ajit