Working on context menu

[dushkin]

Hi all,

I am working on an application which has a list view, and can open a context menu on each one of the list item.

How can I get information about the menu?

I managed to go through the menu items by sending "down" commands. 

But how can I check for example the items text?

I tried this:

$hMenu = _GUICtrlMenu_GetMenu($hListViewHandle)

 

$itemtext =_GUICtrlMenu_GetItemText($hMenu, 1)

 

ConsoleWrite("Menu item text: " & $itemtext & @CRLF)

 

but $itemtext was empty.

 

I think my problem is getting the menu handler, because I am familiar with the _GUICtrlMenu functuions.

Thanks!

[Melba23]

dushkin,

Try this:

#include <WindowsConstants.au3>
#include "SendMessage.au3"
#Include <GuiMenu.au3>

Global $sCurr_Text

While 1

    If WinExists("[CLASS:#32768]") Then

        $hWnd = WinGetHandle("[CLASS:#32768]")

        $hMenu = _SendMessage($hWnd, $MN_GETHMENU, 0, 0)
        If _GUICtrlMenu_IsMenu($hMenu) Then
            $iCount = _GUICtrlMenu_GetItemCount($hMenu)
            For $j = 0 To $iCount - 1
                If _GUICtrlMenu_GetItemHighlighted($hMenu, $j) Then
                    $sText = _GUICtrlMenu_GetItemText($hMenu, $j)
                    If $sText <> $sCurr_Text Then
                        ConsoleWrite($sText & @CRLF)
                        $sCurr_Text = $sText
                    EndIf
                EndIf
            Next
        EndIf

    EndIf

    Sleep(10)

WEnd

It looks for a standard Windows popup and checks if it is a menu.  It works perfectly on standard Windows context menus - let us hope that your ListView uses the API to produce its context menus.

M23

[dushkin]

Well Mel, your'e the greatest! Thanks!!!