Resizing an image (with GDI+)

[nullschritt]

Hello forum, just wondering, if it's possible to resize an image with only GDI+? I need all images to be one size, but the origin image size is not always that size, so it would be optimal to be able to resize all images to a specific size, so the whole image is displayed on the whole control.

[UEZ]

Try this: _GDIPlus_ScaleImage2(). You can modify the function appropriately if you want to scale the bitmap directly instead of loading the bitmap first.

   

Br,

UEZ

Edited August 4, 2013 by UEZ

[Edano]

$ret=DllCall($ghGDIPDll,"int","GdipGetImageThumbnail","ptr",$hImage,"int",$Width,"int",$Height,"ptr*",0,"ptr",0,"ptr",0)
$hImage=$ret[4]

.

with the handle, only one solution among others

[nullschritt]

$ret=DllCall($ghGDIPDll,"int","GdipGetImageThumbnail","ptr",$hImage,"int",$Width,"int",$Height,"ptr*",0,"ptr",0,"ptr",0)
$hImage=$ret[4]

.

with the handle, only one solution among others

So $hImage is the handle to the bitmap object? what is $ghGDIPDll?

[nullschritt]

Try this: _GDIPlus_ScaleImage2(). You can modify the function appropriately if you want to scale the bitmap directly instead of loading the bitmap first.

   

Br,

UEZ

Thanks for your time, but I am looking for a solution to modify an already loaded bitmap(from memory), I think edano's solution might be what I was looking for.

[UEZ]

nullschritt,

as mentioned you need to modify the function appropriately which is really easy to do.

 

Func _GDIPlus_ScaleImage2($hImage, $iNewWidth, $iNewHeight, $iBGColor = 0xFFF0F0F0, $bBGClear = True, $iInterpolationMode = 7) ;coded by UEZ 2012
    Local $iWidth = _GDIPlus_ImageGetWidth($hImage)
    Local $iHeight = _GDIPlus_ImageGetHeight($hImage)

    Local $iW, $iH, $f, $fRatio

    If $iWidth > $iHeight Then
        $f = $iWidth / $iNewWidth
    Else
        $f = $iHeight / $iNewHeight
    EndIf
    $iW = Int($iWidth / $f)
    $iH = Int($iHeight / $f)

    If $iW > $iNewWidth Then
        $fRatio = $iNewWidth / $iW
        $iW = Int($iW * $fRatio)
        $iH = Int($iH * $fRatio)
    ElseIf $iH > $iNewHeight Then
        $fRatio = $iNewHeight / $iH
        $iW = Int($iW * $fRatio)
        $iH = Int($iH * $fRatio)
    EndIf

    Local $hBitmap = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iW, "int", $iH, "int", 0, "int", 0x0026200A, "ptr", 0, "int*", 0)
    If @error Then Return SetError(3, 0, 0)
    $hBitmap = $hBitmap[6]
    Local $hBmpCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    If $bBGClear Then _GDIPlus_GraphicsClear($hBmpCtxt, $iBGColor)
    DllCall($ghGDIPDll, "uint", "GdipSetInterpolationMode", "handle", $hBmpCtxt, "int", $iInterpolationMode)
    _GDIPlus_GraphicsDrawImageRect($hBmpCtxt, $hImage, 0, 0, $iW, $iH)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hBmpCtxt)
    Return $hBitmap
EndFunc

Br,

UEZ

Edited August 5, 2013 by UEZ

[Edano]

in any case, $ghGDIPDll is the variable of the handle to gdiplus.dll that is globally assigned declared by calling _GDIPlusStartUp(). see _GDIPlus.au3 in the includes folder.

Edited August 5, 2013 by Edano