STDOUT in a GUICtrlEdit

[lavascript]

#include <Constants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1)  ; Change to OnEvent mode

Dim $hWin = GUICreate("Ping",400,200)
Dim $hEdit = GUICtrlCreateEdit("",5,5,390,190);,$GUI_SS_DEFAULT_EDIT - $WS_HSCROLL + $ES_READONLY)

GUISetOnEvent($GUI_EVENT_CLOSE, "_Die")

GUISetState(@SW_SHOW)

_Ping("10.120.9.79")

While True
    Sleep(1000)
WEnd

Func _Ping($Target)
    Local $hWndCmd = Run(@ComSpec & " /c ping " & $Target, @SW_HIDE, $STDIN_CHILD + $STDERR_MERGED)
    Local $sCmdOutput
    While True
        $sCmdOutput &= StdoutRead($hWndCmd)
        If @error Then ExitLoop
        GUICtrlSet($hEdit,$sCmdOutput,1)
    WEnd

    MsgBox(0,Default,$sCmdOutput)
EndFunc

Func _Die()
    GUIDelete($hWin)
    Exit
EndFunc

I want to use this functionality elsewhere, but for now I'm testing with PING. Why won't this work? I just want to run a CLI command and display the output in an edit control.

Thoughts?

 

[BrewManNH]

First things first, there's no function GUICtrlSet, you're looking for GUICtrlSetData.

Second, you have @SW_HIDE in the "working dir" parameter and the last parameter is in the "show_flag" parameter.

Third, do you want this to update as it's running, or after the ping command has finished, or does it matter?

The code below shows both methods regarding point #3, you can choose one or the other, or both for that matter because the second one will overwrite the first one's entries with the total received text.

expandcollapse popup

#include <Constants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

Dim $hWin = GUICreate("Ping", 400, 200)
Dim $hEdit = GUICtrlCreateEdit("", 5, 5, 390, 190);,$GUI_SS_DEFAULT_EDIT - $WS_HSCROLL + $ES_READONLY)

GUISetOnEvent($GUI_EVENT_CLOSE, "_Die")

GUISetState(@SW_SHOW)

_Ping("yahoo.com")

While True
    Sleep(1000)
WEnd

Func _Die()
    GUIDelete($hWin)
    Exit
EndFunc   ;==>_Die

Func _Ping($Target)
    Local $hWndCmd = Run(@ComSpec & " /c ping " & $Target, "", @SW_HIDE, $STDIN_CHILD + $STDERR_MERGED)
    Local $sCmdOutput= "", $LastCmdOutput = ""
    While True
        $sCmdOutput &= StdoutRead($hWndCmd)
        If @error Then ExitLoop
        ; this section will display it as it is being read
        If $sCmdOutput <> $LastCmdOutput Then
            GUICtrlSetData($hEdit, $sCmdOutput)
            $LastCmdOutput = $sCmdOutput
        EndIf
        ; end section
    WEnd
    GUICtrlSetData($hEdit, $sCmdOutput) ; this will display it after the ping command has finished

;~  MsgBox(0, Default, $sCmdOutput)
EndFunc   ;==>_Ping

[lavascript]

(For the record, I had removed the GUICtrlSetData from the script during testing and typo'd when I typed it back into the forum)

And THANK YOU. I had copied that code from a script I wrote last year that I KNEW was working. Missed a daggum comma.

[BrewManNH]

Glad it's working for you, punctuation can always cause all sorts of problems.