GUICtrlSetState help

[Cravin]

Howdy,

I've been digging around on the forums trying to find a good way to disable checkboxes using a radio button.  Thanks to some information posted by BrewManNH, I've been able to successfully find a way to do this, however, I'd like to see if anyone has any thoughts on making the code I currently have less ugly - I've tried a few different things and I'm having a slightly difficult time trying to find a good way to cut down the length.  Any help would be greatly appreciated!

Specifically, I'd like help with the following items:

1) Converting the While loop near the bottom from If statements to Switch...Case or Select...Case so that I can add additional case statements (for other controls such as buttons, shortcut keys, etc if possible.

2) Using an array for $Checkbox1-10 to enable/disable the checkboxes versus having 10+ lines to do the same

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $Radio1,$Radio2,$Radio3,$Radio4,$Checkbox,$Checkbox1,$CheckBox2,$Checkbox3,$Checkbox4,$Checkbox5,$Checkbox6,$Checkbox7,$Checkbox8,$Checkbox9,$Checkbox10,$Main,$Radio1Status,$Radio2Status,$LastRadio1Status,$LastRadio2Status

$Main = GUICreate("TEST", 432, 556, 212, 153)
$Group2 = GUICtrlCreateGroup("", 24, 200, 377, 65)
GUIStartGroup()
$Radio1 = GUICtrlCreateRadio("Radio1", 56, 216, 129, 17)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$Radio2 = GUICtrlCreateRadio("Radio2", 248, 216, 105, 17)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUIStartGroup()
$Radio3 = GUICtrlCreateRadio("Radio3", 56, 240, 57, 17)
$Radio4 = GUICtrlCreateRadio("Radio4", 120, 240, 65, 17)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group3 = GUICtrlCreateGroup("", 24, 288, 377, 177)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 72, 312, 89, 17)
$Checkbox2 = GUICtrlCreateCheckbox("Checkbox2", 168, 312, 89, 17)
$Checkbox3 = GUICtrlCreateCheckbox("Checkbox3", 272, 312, 97, 17)
$Checkbox4 = GUICtrlCreateCheckbox("Checkbox4", 72, 336, 89, 17)
$Checkbox5 = GUICtrlCreateCheckbox("Checkbox5", 168, 336, 89, 17)
$Checkbox6 = GUICtrlCreateCheckbox("Checkbox6", 272, 336, 105, 17)
$Checkbox7 = GUICtrlCreateCheckbox("Checkbox7", 72, 360, 89, 17)
$Checkbox8 = GUICtrlCreateCheckbox("Checkbox8", 168, 360, 89, 17)
$Checkbox9 = GUICtrlCreateCheckbox("Checkbox9", 72, 384, 89, 17)
$Checkbox10 = GUICtrlCreateCheckbox("Checkbox10", 168, 384, 89, 17)
GUISetState()

    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        $Radio1Status = GUICtrlRead($radio1)
        $Radio2Status = GUICtrlRead($radio2)
        If $Radio1Status = $GUI_CHECKED Then
            If $Radio1Status <> $LastRadio1Status Then
                $LastRadio1Status = $Radio1Status
                GUICtrlSetState($Checkbox1, $GUI_DISABLE)
                GUICtrlSetState($Checkbox2, $GUI_DISABLE)
                GUICtrlSetState($Checkbox3, $GUI_DISABLE)
                GUICtrlSetState($Checkbox4, $GUI_DISABLE)
                GUICtrlSetState($Checkbox5, $GUI_DISABLE)
                GUICtrlSetState($Checkbox6, $GUI_DISABLE)
                GUICtrlSetState($Checkbox7, $GUI_DISABLE)
                GUICtrlSetState($Checkbox8, $GUI_DISABLE)
                GUICtrlSetState($Checkbox9, $GUI_DISABLE)
                GUICtrlSetState($Checkbox10, $GUI_DISABLE)
                GUICtrlSetState($Radio3, $GUI_ENABLE)
                GUICtrlSetState($Radio4, $GUI_ENABLE)

            EndIf
        Else
            If $Radio1Status <> $LastRadio1Status Then
                $LastRadio1Status = $Radio1Status
            EndIf
        EndIf
        If $Radio2Status = $GUI_CHECKED Then
            If $Radio2Status <> $LastRadio2Status Then
                $LastRadio2Status = $Radio2Status
                GUICtrlSetState($Checkbox1, $GUI_ENABLE)
                GUICtrlSetState($Checkbox2, $GUI_ENABLE)
                GUICtrlSetState($Checkbox3, $GUI_ENABLE)
                GUICtrlSetState($Checkbox4, $GUI_ENABLE)
                GUICtrlSetState($Checkbox5, $GUI_ENABLE)
                GUICtrlSetState($Checkbox6, $GUI_ENABLE)
                GUICtrlSetState($Checkbox7, $GUI_ENABLE)
                GUICtrlSetState($Checkbox8, $GUI_ENABLE)
                GUICtrlSetState($Checkbox9, $GUI_ENABLE)
                GUICtrlSetState($Checkbox10, $GUI_ENABLE)
                GUICtrlSetState($Radio3, $GUI_DISABLE)
                GUICtrlSetState($Radio4, $GUI_DISABLE)
                GUICtrlSetState($Radio3, $GUI_UNCHECKED)
                GUICtrlSetState($Radio4, $GUI_UNCHECKED)
            EndIf
        Else
            If $Radio2Status <> $LastRadio2Status Then
                $LastRadio2Status = $Radio2Status
            EndIf
        EndIf

    WEnd

Again, thanks in advance for any thoughts - and if any clarification is needed, please let me know!

~ Cravin

[TheSaint]

It can seem ugly, but it is effective.

However, if you are concerned about number of lines, typing, copying etc, then one method is the Assign command inside a loop.

i.e.

For $a = 1 to 10

     $checkbox = Assign("Checkbox" & $a)

     GuiCtrlSetState($checkbox, $GUI_DISABLE)

Next

Edited August 28, 2013 by TheSaint

[Cravin]

Had to adjust the code a bit but the following worked for solving question #2, much obliged, TheSaint!

For $a = 1 to 10
     $checkbox = Assign("Checkbox" & $a, "", 2)
     GuiCtrlSetState($checkbox, $GUI_DISABLE)
Next

Now, how about for the first question, any thoughts?  I need to be able to maintain the functionality of the radio buttons and checkboxes while adding additional "case" events.  How can I format the While loop to add this?

[BrewManNH]

Try this.

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $Radio1, $Radio2, $Radio3, $Radio4, $Checkbox[11], $Checkbox1, $CheckBox2, $Checkbox3
Global $Checkbox4, $Checkbox5, $Checkbox6, $Checkbox7, $Checkbox8, $Checkbox9, $Checkbox10
Global $Main, $Radio1Status, $Radio2Status, $LastRadio1Status, $LastRadio2Status

$Main = GUICreate("TEST", 432, 556, 212, 153)
$Group2 = GUICtrlCreateGroup("", 24, 200, 377, 65)
GUIStartGroup()
$Radio1 = GUICtrlCreateRadio("Radio1", 56, 216, 129, 17)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$Radio2 = GUICtrlCreateRadio("Radio2", 248, 216, 105, 17)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUIStartGroup()
$Radio3 = GUICtrlCreateRadio("Radio3", 56, 240, 57, 17)
$Radio4 = GUICtrlCreateRadio("Radio4", 120, 240, 65, 17)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group3 = GUICtrlCreateGroup("", 24, 288, 377, 177)
$CheckBox[1] = GUICtrlCreateCheckbox("Checkbox1", 72, 312, 89, 17)
$CheckBox[2] = GUICtrlCreateCheckbox("Checkbox2", 168, 312, 89, 17)
$CheckBox[3] = GUICtrlCreateCheckbox("Checkbox3", 272, 312, 97, 17)
$CheckBox[4] = GUICtrlCreateCheckbox("Checkbox4", 72, 336, 89, 17)
$CheckBox[5] = GUICtrlCreateCheckbox("Checkbox5", 168, 336, 89, 17)
$CheckBox[6] = GUICtrlCreateCheckbox("Checkbox6", 272, 336, 105, 17)
$CheckBox[7] = GUICtrlCreateCheckbox("Checkbox7", 72, 360, 89, 17)
$CheckBox[8] = GUICtrlCreateCheckbox("Checkbox8", 168, 360, 89, 17)
$CheckBox[9] = GUICtrlCreateCheckbox("Checkbox9", 72, 384, 89, 17)
$CheckBox[10] = GUICtrlCreateCheckbox("Checkbox10", 168, 384, 89, 17)
GUISetState()

While GUIGetMsg() <> $GUI_EVENT_CLOSE
    $Radio1Status = GUICtrlRead($Radio1)
    $Radio2Status = GUICtrlRead($Radio2)
    If $Radio1Status = $GUI_CHECKED Then
        If $Radio1Status <> $LastRadio1Status Then
            $LastRadio1Status = $Radio1Status
            For $I = 1 to 10
                GUICtrlSetState($Checkbox[$I], $GUI_DISABLE)
            Next
            GUICtrlSetState($Radio3, $GUI_ENABLE)
            GUICtrlSetState($Radio4, $GUI_ENABLE)
        EndIf
    Else
        If $Radio1Status <> $LastRadio1Status Then
            $LastRadio1Status = $Radio1Status
        EndIf
    EndIf
    If $Radio2Status = $GUI_CHECKED Then
        If $Radio2Status <> $LastRadio2Status Then
            $LastRadio2Status = $Radio2Status
            For $I = 1 to 10
                GUICtrlSetState($Checkbox[$I], $GUI_ENABLE)
            Next
            GUICtrlSetState($Radio3, BitOR($GUI_DISABLE, $GUI_UNCHECKED))
            GUICtrlSetState($Radio4, BitOR($GUI_DISABLE, $GUI_UNCHECKED))
        EndIf
    Else
        If $Radio2Status <> $LastRadio2Status Then
            $LastRadio2Status = $Radio2Status
        EndIf
    EndIf
WEnd

[Cravin]

That's definitely a more elegant solution, thanks BrewManNH!  As always, I owe you.

~ Cravin

[TheSaint]

Yes, that's the other (main) way.

However, Assign often gets lonely.

Sorry about the parameters, I probably should have checked, rather than rely on my memory from older versions.

[Cravin]

Not a problem Saint, I appreciate the feedback either way.  Got me headed down a better path than the one I was on!