Simple anti-auto-logout script

[SpookMeister]

I created this script to keep from being logged out of a game called Runescape. They have an annoying "feature" that auto logs you off of the game if you are idle for more than 90 seconds. I found that moving the mouse even a little periodically is enough to abort that, so here was my solution. I went to extra lengths to keep it unobtrusive during active use and random in its timing and activity to avoid raising flags from the Game Gestapo.

expandcollapse popup

; ----------------------------------------------------------------------------
;
; AutoIt Version: 3.1.0
; Author:        SpookMeister <myemail@nowhere.com>
;
; Script Function:
;   Periodically moves the mouse to avoid being auto logged out of games 
;   (screensavers too).
;
; ----------------------------------------------------------------------------


; Press ESC to terminate program
HotKeySet("{ESC}", "Terminate")

Global $LastPosX
Global $LastPosY
Global $CurPosX
Global $CurPosY

$pos = MouseGetPos()
$LastPosX = $pos[0]
$LastPosY = $pos[1]

; Main loop
WHILE 1
   $sec = Random(30,45,1)
   sleep($sec * 1000)
   CheckMove()
WEND

; See if the mouse has moved since the last time checked
Func CheckMove()
   $pos = MouseGetPos()
   $CurPosX = $pos[0]
   $CurPosY = $pos[1]
   IF $CurPosX = $LastPosX AND $CurPosY = $LastPosY THEN DoSomeThing()
  ; Update vars to be able to detect changes on next iteration 
   $LastPosX = $CurPosX 
   $LastPosY = $CurPosY
EndFunc


Func DoSomething()
  ; Make sure you don't get a null movement if random returns 0 for both coords
   Do
      $ranX = Random(-1,1,1)
      $ranY = Random(-1,1,1)
   Until $ranX <> 0 AND $ranY <> 0
   MouseMove($CurPosX + $ranX, $CurPosY + $ranY)
   MouseMove($CurPosX , $CurPosY)
EndFunc

Func Terminate()
   EXIT
EndFunc

[LxP]

Welcome to the forums!

Nicely written script -- I like how it doesn't intervene if there has been activity and I like the way you've broken it down into functions.

[theguy0000]

nice script, useful!

- Matt