Check to see if any checkboxes are checked

[thexshadow]

I know there is a way to do this, I did it a long time ago, i just cant remember how to do it.

When any one of my checkboxes are checked it will popup with a go message and when none are checked it comes up with an error.

If GuiCtrlRead($Chk1) = $GUI_UNCHECKED Then
    MsgBox(0, "Error", "Please Check Something!")
Else
    MsgBox(0, "Completed", "Completed!")
EndIf

So on the first line it should be something like this, but I know that wont work. I cant remember but maybe I used a "BIT" like "BITOR" or something like that.

If GuiCtrlRead($Chk1 or $Chk2) = $GUI_UNCHECKED Then

Any ideas?

[somdcomputerguy]

I'm sure there are other ways, but this works for me..

If BitAnd(GUICtrlRead($Chk1), $GUI_CHECKED) Then

[AdamUL]

Try this.
 

If BitAND(GuiCtrlRead($Chk1), $GUI_UNCHECKED) = $GUI_UNCHECKED Then
    MsgBox(0, "Error", "Please Check Something!")
Else
    MsgBox(0, "Completed", "Completed!")
EndIf

 

Adam

[TheSaint]

Without seeing your whole script and knowing things like the number of Checkboxes you want checked, I just offer the following simple example.

If GuiCtrlRead($Chk1) = $GUI_UNCHECKED or GuiCtrlRead($Chk2) = $GUI_UNCHECKED Then

Edited October 1, 2013 by TheSaint

[PhoenixXL]

When any one of my checkboxes are checked it will popup with a go message and when none are checked it comes up with an error.

 

Then you would have to use an loop( recommended FOR - NEXT loop ) to check each control. I don't think there is something using BitOR or stuff like that...

Example

expandcollapse popup

#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $msg
    GUICreate("My GUI Checkbox") ; will create a dialog box that when displayed is centered

    ;I created all the checkboxes(in sequence i.e. one after the other) using a For Loop
    ;so that I can use the controlID of the First and the Last
    ;when verifying that at least a single checkbox is checked.


    ;You can even use an array to store all your check boxes's controlID
    ;and use it while verifying in the for loop.
    Local $iFirst = GUICtrlCreateCheckbox("CHECKBOX 1", 10, 5, 120, 20)
    For $i = 0 To 6
        GUICtrlCreateCheckbox("CHECKBOX " & $i + 2, 10, 30 * ($i + 1) + 2, 120, 20)
    Next
    Local $iLast = GUICtrlCreateCheckbox("CHECKBOX 9", 10, 30 * ($i + 1) + 2, 120, 20)

    GUISetState() ; will display an  dialog box with 1 checkbox

    ; Run the GUI until the dialog is closed
    Do
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE Then

            ;=====================================================================================
            ;Note this part is the important and required part
            For $i = $iFirst To $iLast
                If GUICtrlRead($i) = $GUI_CHECKED Then
                    Return MsgBox(0, "Completed", "Completed!"); atleast one is checked.
                EndIf
            Next

            ;reached here that means nothing is checked.
            MsgBox(16, "Error", "Please Check Something!")  ;show the error and continue the loop
            ;======================================================================================

        EndIf

    Until 0



EndFunc   ;==>Example

Note: When Controls are created the return value is the ControlID(an integer uniquely identifying the control) and this integer is relative to the sequence of controls created( ==> if the first checkbox is assigned a ControlID say '5' then the second is assigned a ControlID '6' and so on...) .

Hence, it is very easy to use the ControlID of the first and last checkbox created in a For-Next loop.

Regards

Edited October 1, 2013 by PhoenixXL