Sign in to follow this  
Followers 0
l3ill

_GUICtrlRichEdit_FindText (F3) or Find Next

3 posts in this topic

Hi,

  looking for a way to search through a txt file in a _GUICtrlRichEdit_Create like you can with F3 (find next) where you just click through each found item until you get to the one you are looking for. (for example find in scite works like this).

  I found >this but its not what I'm looking for. It changes the button which I dont mind but it runs out after 2 searches.

Any help would be appreciated!

Bill

Share this post


Link to post
Share on other sites



billo,

Pretty easy to fix that: ;)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiRichEdit.au3>

Global $sText = "This is a line." & @CRLF & _
            "And this is another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line." & @CRLF & _
            "And yet another line."

Main()

Func Main()

    Local $sLastSearch = ""
    Local $iSearchStart = 0

    Local $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)

    Local $hRichEdit = _GUICtrlRichEdit_Create($hGui, $sText, 10, 10, 300, 220, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))

    Local $cSearch_Input = GUICtrlCreateInput("", 10, 300, 200, 20)
    Local $cFind_Button = GUICtrlCreateButton("Find", 230, 300, 80, 30)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
            Case $cFind_Button
                ; Get search term
                $sSearchTerm = GUICtrlRead($cSearch_Input)
                If $sSearchTerm Then
                    ; If new search then reset start
                    If $sSearchTerm <> $sLastSearch Then
                        $iSearchStart = 0
                        $sLastSearch = $sSearchTerm
                    EndIf
                    _GUICtrlRichEdit_SetSel($hRichEdit, $iSearchStart, $iSearchStart)
                    $iIndex = _GUICtrlRichEdit_FindText($hRichEdit, $sSearchTerm)
                    _GUICtrlRichEdit_SetSel($hRichEdit, $iIndex, $iIndex + StringLen($sSearchTerm))
                    $iSearchStart = $iIndex + StringLen($sSearchTerm)
                EndIf

        EndSwitch
    WEnd
EndFunc   ;==>Main
M23

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0