Sign in to follow this  
Followers 0
qazwsx123

How I get item handle after click (on ListViev)

3 posts in this topic

Hi, how I get item handle/text and activate function after click (on ListViev item) ?

Share this post


Link to post
Share on other sites



qazwsx123,

Welcome to the AutoIt forum. :)

You can do it like this:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 250, 250)

$cListView = GUICtrlCreateListView("Column 0|Column 1|Column 2", 10, 10, 230, 160)
For $i = 0 To 5
    GUICtrlCreateListViewItem("Item " & $i & "0|Item " & $i & "1|Item " & $i & "2", $cListView)
Next

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd


Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $wParam

    Local $tStruct = DllStructCreate("hwnd;uint_ptr;int_ptr;int;int", $lParam)
    If @error Then Return
    Switch DllStructGetData($tStruct, 3)
        Case $NM_CLICK
            ConsoleWrite("Row: " & DllStructGetData($tStruct, 4) & " - Col: " &DllStructGetData($tStruct, 5) & @CRLF)
    EndSwitch

EndFunc   ;==>On_WM_NOTIFY
If you are not used to working with Windows message handlers I recommend the GUIRegisterMsg tutorial in the Wiki. ;)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

If you are lazy enough to learn WM (like me :)) then you can try this:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("Test", 280, 250)

$cListView = GUICtrlCreateListView("Column 0|Column 1|Column 2", 10, 10, 260, 160)
For $i = 0 To 5
    GUICtrlCreateListViewItem("Item " & $i & "0|Item " & $i & "1|Item " & $i & "2", $cListView)
Next

GUISetState()

Local $winHandle = GUICtrlGetHandle ( $hGUI )

While 1
    $nMsg = GUIGetMsg()

    If $nMsg = $GUI_EVENT_PRIMARYDOWN Then
        $handleOfObject = GUIGetCursorInfo ( $winHandle )
        if Not @error Then
            If $handleOfObject[4] = $cListView Then $nMsg = $cListView
        EndIf
    EndIf

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $cListView
            $iIndex = _GUICtrlListView_GetSelectionMark($cListView)
            $text = _GUICtrlListView_GetItemTextString($cListView, $iIndex )
            MsgBox(64,"Item text",$text)

    EndSwitch
WEnd

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0