Sign in to follow this  
Followers 0
Luigi

Is possible flash only one part's of _GUICtrlStatusBar_Create?

4 posts in this topic

Hi Forum,

In this little example, I use _GUICtrlStatusBar_SetBkColor to flash the status bar, but, this idea flash all status bar parts's.

Is possible flash only one part at each time?

Flash only 'Part I' and not another parts?

Thank you!

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>

Global $hGui, $hMsg, $hStatus

$hGui = GUICreate('title', 800, 600)
Local $a_Status_Part[3] = [266, 532, -1]

$hStatus = _GUICtrlStatusBar_Create($hGui)
_GUICtrlStatusBar_SetParts($hStatus, $a_Status_Part)
_GUICtrlStatusBar_SetText($hStatus, 'Part I', 0)
_GUICtrlStatusBar_SetText($hStatus, 'Part II', 1)
_GUICtrlStatusBar_SetText($hStatus, 'Part III', 2)

GUISetState(@SW_SHOWNORMAL)
AdlibRegister('flash', 500)

While 1
    $hMsg = GUIGetMsg()
    Switch $hMsg
        Case $GUI_EVENT_CLOSE
            _exit()
    EndSwitch
WEnd

Func _exit()
    AdlibUnRegister('flash')
    GUIDelete($hGui)
    Exit
EndFunc   ;==>_exit

Func flash()
    Local Static $toggle = 1
    If $toggle Then
        $toggle = 0
        _GUICtrlStatusBar_SetBkColor($hStatus, 0x0000ff)
    Else
        $toggle = 1
        _GUICtrlStatusBar_SetBkColor($hStatus, 0xD4D0C8)
    EndIf
EndFunc   ;==>flash

Visit my repository

Share this post


Link to post
Share on other sites



Detefon,

How about this little trick? ;)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiStatusBar.au3>

Global $hGui, $hMsg, $hStatus
Global $iGUIHeight = 600

$hGui = GUICreate('title', 800, $iGUIHeight)

Local $a_Status_Part[3] = [266, 532, -1]

$hStatus = _GUICtrlStatusBar_Create($hGui)
_GUICtrlStatusBar_SetParts($hStatus, $a_Status_Part)
_GUICtrlStatusBar_SetText($hStatus, 'Part I', 0)
_GUICtrlStatusBar_SetText($hStatus, 'Part II', 1)
_GUICtrlStatusBar_SetText($hStatus, 'Part III', 2)

GUISetState(@SW_SHOWNORMAL)

$iStatusHeight = _GUICtrlStatusBar_GetHeight($hStatus) + (_GUICtrlStatusBar_GetBordersVert($hStatus) * 2)
$aRect = _GUICtrlStatusBar_GetRect($hStatus, 0)
$hMask = GUICreate("", $aRect[2] - $aRect[0], $aRect[3] - $aRect[1], 0, $iGUIHeight - $iStatusHeight, $WS_POPUP, $WS_EX_MDICHILD, $hGui)
GUISetBkColor(0xFF0000)
WinSetTrans($hMask, "", 0)
GUISetState()

AdlibRegister('flash', 500)

While 1
    $hMsg = GUIGetMsg()
    Switch $hMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func flash()
    Local Static $toggle = 1
    If $toggle Then
        $toggle = 0
        WinSetTrans($hMask, "", 100)
    Else
        $toggle = 1
        WinSetTrans($hMask, "", 0)
    EndIf
EndFunc   ;==>flash
Good enough? :)

M23

1 person likes this

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Ohhhhh! A new Gui above old Gui?

Flashing with transparence?

I thinking the final effect is better than _GUICtrlStatusBar_SetBkColor!

I like this! 8D

Thank you Melba23! 


Visit my repository

Share this post


Link to post
Share on other sites

Reading another GuiStatusbar's functions, I found _GUICtrlStatusBar_EmbedControl.

I not try yet, maybe is possible embed any kind flash control in status bar too.

Is not flash native, but, may work like this.


Visit my repository

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0