regexp help

[wisem2540]

I have a block of text, as follows

File-based write filter configuration for the current session:
    filter state: enabled.
    overlay cache data compression state: enabled.
    overlay cache threshold: 128 MB.
    overlay cache pre-allocation: disabled.
    size display: actual mode.
    protected volume list: (none)
    write through list of each protected volume:

File-based write filter configuration for the next session:
    filter state: enabled.
    overlay cache data compression state: enabled.
    overlay cache threshold: 128 MB.
    overlay cache pre-allocation: disabled.
    size display: actual mode.
    protected volume list: (none)
    write through list of each protected volume:

All I want to return is Current session filter state, like this piece...

File-based write filter configuration for the current session:
    filter state: enabled.
 

I figure I could end at the period after "Enabled"

So I tried this...

File-based write filter configuration for the current session:([^/]+)\.

However, this returns all the way to file FINAL period in the block of text.  I want it to stop at the FIRST period.  Can anyone help?

[jguinch]

Something like this ?

#Include <Array.au3>

$sText = "File-based write filter configuration for the current session:" & @CRLF &  _ 
         "filter state: enabled." & @CRLF &  _ 
         "overlay cache data compression state: enabled." & @CRLF &  _ 
         "overlay cache threshold: 128 MB." & @CRLF &  _ 
         "overlay cache pre-allocation: disabled." & @CRLF &  _ 
         "size display: actual mode." & @CRLF &  _ 
         "protected volume list: (none)" & @CRLF &  _ 
         "write through list of each protected volume:" & @CRLF &  _ 
         @CRLF &  _ 
         "File-based write filter configuration for the next session:" & @CRLF &  _ 
         "filter state: enabled." & @CRLF &  _ 
         "overlay cache data compression state: enabled." & @CRLF &  _ 
         "overlay cache threshold: 128 MB." & @CRLF &  _ 
         "overlay cache pre-allocation: disabled." & @CRLF &  _ 
         "size display: actual mode." & @CRLF &  _ 
         "protected volume list: (none)" & @CRLF &  _ 
         "write through list of each protected volume:"

ConsoleWrite($sText)


$aFilterSession = StringRegExp($sText, "(?i)File-based write filter configuration for the current session:\R\h*filter state:\h*([^.]+)", 1)

; or
; $aFilterSession = StringRegExp($sText, "(?is)current session:.+?((?:en|dis)+abled)", 1)
; or ... else ...

_ArrayDisplay($aFilterSession)

Edited September 24, 2014 by jguinch

[Melba23]

wisem2540,

Or perhaps this:

$sText = "File-based write filter configuration for the current session:" & @CRLF &  _
         "filter state: enabled." & @CRLF &  _
         "overlay cache data compression state: enabled." & @CRLF &  _
         "overlay cache threshold: 128 MB." & @CRLF &  _
         "overlay cache pre-allocation: disabled." & @CRLF &  _
         "size display: actual mode." & @CRLF &  _
         "protected volume list: (none)" & @CRLF &  _
         "write through list of each protected volume:" & @CRLF &  _
         @CRLF &  _
         "File-based write filter configuration for the next session:" & @CRLF &  _
         "filter state: enabled." & @CRLF &  _
         "overlay cache data compression state: enabled." & @CRLF &  _
         "overlay cache threshold: 128 MB." & @CRLF &  _
         "overlay cache pre-allocation: disabled." & @CRLF &  _
         "size display: actual mode." & @CRLF &  _
         "protected volume list: (none)" & @CRLF &  _
         "write through list of each protected volume:"

$sFilterSession = StringRegExpReplace($sText, "(?Us)^(.*\.).*$", "$1")

ConsoleWrite($sFilterSession & @CRLF)

M23

[mikell]

$sFilterSession = StringRegExp($sText, "(?is)current.*?state:\h*([^.]+)", 1)[0]
Msgbox(0,"", $sFilterSession)

Edited September 24, 2014 by mikell

[wisem2540]

I used Mikell's example.

Thank you all!