Parsing with StringRegExp

[methodman]

I've spent a few hours on this one and I can't get it exactly right (just almost right...)

$string = "+ST,000024.4 g"

$asResult = StringRegExp($string, "[-+]?\d*\.\d+|\d+",2)
If @error == 0 Then
    MsgBox(0, "Result", $asResult[0])
EndIf

The result is 000024.4 which is OK - I'd like the code to be 24.4 however.

Tricky part is that it the string can look like +ST,010232.2 g, or even +UT,000000.4 g (looking for 10232.2 and .4 respectively out of those 2 eg's)

Edited October 16, 2014 by methodman

[Zedna]

The result is 000024.4 which is OK - I'd like the code to be 24.4 however.

 

MsgBox(0, "Result", Number($asResult[0]))

 

[Zedna]

With RegExp I would use this:

$string = "+ST,000024.4 g"
;$string = "+UT,010232.2 g"

$asResult = StringRegExpReplace($string, "[-+]?\D*(\d*\.\d+|\d+)\sg",'$1')
MsgBox(0, "Result", Number($asResult))

[funkey]

This is the way I would do it:

$string = "+ST,000024.4 g"
;~ $string = "+UT,010232.2 g"


Global $asResult = StringSplit($string, ",", 3)
MsgBox(0, "result", Number($asResult[1]))

[mikell]

$string = "+ST,000024.4 g"

$asResult = StringRegExp($string, "[\d.]+", 3)
MsgBox(0, "Result", Number($asResult[0]))

[Malkey]

I believe we all agree the Number() function is the way to remove leading zeros and any trailing non-digit characters.

$string = "+ST,001024.4 g" ; "+UT,000000.4 g" ;

MsgBox(0, "Result RegExp", Number(StringRegExpReplace($string, "^.*,|\s.*$", '')), 3) ; Returns 1024.4

;or

MsgBox(0, "Result StringSplit", Number(StringSplit($string, ",", 3)[1])) ; Returns 1024.4

@methodman

If $string = "-ST,001024.4 g", hopefully you do not want -1024.4 returned - yes/no?

[jguinch]

Tricky part is that it the string can look like +ST,010232.2 g, or even +UT,000000.4 g (looking for 10232.2 and .4 respectively out of those 2 eg's)

 

For the .4 value, Number() will add a 0 at the beginning, so maybe just this :

$string = "+UT,000000.4 g"
; $string = "+ST,010232.2 g"

$asResult = StringRegExp($string, "0*([\d.]+)", 1)
MsgBox(0, "Result", $asResult[0])

[methodman]

Thanks a million to you all - couldn't have asked for a more helpful response.

[methodman]

I was actually after 0.4 - figured it might be difficult to achieve so would have been OK with .4

Thanks for your efforts nonetheless!

 

For the .4 value, Number() will add a 0 at the beginning, so maybe just this :

$string = "+UT,000000.4 g"
; $string = "+ST,010232.2 g"

$asResult = StringRegExp($string, "0*([\d.]+)", 1)
MsgBox(0, "Result", $asResult[0])