How to capture system tray popup bubble text using autoIt script

[MattiS]

Hello,

 

We have a project requirement to capture system tray popup bubble text using AutoIt script. Script is ready for clicking system tray icon but, unable to capture bubble text.

 

Any inputs/suggestions would be appreciated.

 

Thanks in advance...

 

Regards,

Matti

[junkew]

welcome 

see FAQ question 31

https://www.autoitscript.com/wiki/FAQ

part on iuiautomation with simplespy will help you in the right direction

1. start simplespy

2. hover over your popupbubble text

3. see the sample source the spy puts in the output box

4. for help post that output here

[BrewManNH]

I posted this a while back that should help.

Just replace @ScriptName with the program name you're looking for.

expandcollapse popup

#include <GuiToolBar.au3>

Opt("TrayIconDebug", 1)
HotKeySet("p", "My_Tooltip")
For $Loop = 1 To 1000000
    $a = Sqrt($Loop)
    ; the following line is used to slow the script down enough to be able to press the hotkey
    sleep(10)
Next
Func My_Tooltip()
    $Text = Get_SysTray_IconText(@ScriptName)
    If $Text = "" Then
        MsgBox(0, "", "Icon not found")
    Else
        ToolTip($Text, 20, 20)
    EndIf
EndFunc   ;==>My_Tooltip

Func Get_SysTray_IconText($sScriptName = @ScriptName) ; http://www.autoitscript.com/forum/topic/157933-hinttray-tip-how-to-get-text/?p=1145366

    ; Find systray handle for "User Promoted Notification Area"
    Local $hSysTray_Handle = ControlGetHandle('[Class:Shell_TrayWnd]', '', '[Class:ToolbarWindow32;Instance:1]')
    If @error Then
        MsgBox(16, "Error", "System tray not found")
        Exit
    EndIf
    ; Find systray handle for "Overflow Notification Area" i.e. hidden icons
    Local $hSysTray_Handle_Hidden = ControlGetHandle('[Class:NotifyIconOverflowWindow]', '', '[Class:ToolbarWindow32;Instance:1]')
    If @error Then
        MsgBox(16, "Error", "System tray not found")
        Exit
    EndIf

    ; Get systray item count
    Local $iSysTray_ButCount = _GUICtrlToolbar_ButtonCount($hSysTray_Handle)
    If $iSysTray_ButCount = 0 Then
        MsgBox(16, "Error", "No items found in system tray")
        Exit
    EndIf

    Local $sSysTray_ButtonText = ""
    ; Look for wanted tooltip
    For $iSysTray_ButtonNumber = 0 To $iSysTray_ButCount - 1
        $sSysTray_ButtonText = _GUICtrlToolbar_GetButtonText($hSysTray_Handle, $iSysTray_ButtonNumber)
        If StringInStr($sSysTray_ButtonText, $sScriptName) Then Return $sSysTray_ButtonText
    Next

    Local $iSysTray_ButCount = _GUICtrlToolbar_ButtonCount($hSysTray_Handle_Hidden)
    If $iSysTray_ButCount = 0 Then
        MsgBox(16, "Error", "No items found in system tray")
        Exit
    EndIf
    Local $sSysTray_ButtonText = ""

    ; Look for wanted tooltip
    For $iSysTray_ButtonNumber = 0 To $iSysTray_ButCount - 1
        $sSysTray_ButtonText = _GUICtrlToolbar_GetButtonText($hSysTray_Handle_Hidden, $iSysTray_ButtonNumber)
        If StringInStr($sSysTray_ButtonText, $sScriptName) Then Return $sSysTray_ButtonText
    Next

    Return ""

EndFunc   ;==>Get_SysTray_IconText