Regex split string

[ale1981]

Is it possible to split a string in to an array using a single Regex expression?

I have a string like "C1 X1 B2"

I would like to split the string in to a 2D array like;

$array[0][1] = C

$array[0][2] = 1

$array[1][1] = X

$array[1][2] = 1

$array[2][1] = B

$array[2][2] = 2

 

Thanks in advance.

[BrewManNH]

StringRegExp returns a 1D array, you'd need to convert that to a 2D on your own.

[jdelaney]

Out of the box, you can create an array of arrays:

#include <Array.au3>
$aaValues = StringRegExp("C1 X1 B2","(\w)(\d)",4)
For $i = 0 To UBound($aaValues)-1
    _ArrayDisplay($aaValues[$i])
Next

Edited October 29, 2014 by jdelaney

[Exit]

No RegEx, but working:

#include <array.au3>
_Example("C1 X1 B2")
_Example("C1   XYZ23 A B2")

Func _Example($string)
    $aOrg = StringSplit(StringStripWS($string, 7), " ", 2)
    $dim = 0
    For $i = 0 To UBound($aOrg) - 1
        $dim = (StringLen($aOrg[$i]) > $dim ? StringLen($aOrg[$i]) : $dim)
    Next
    Local $array[UBound($aOrg)][$dim]
    For $i = 0 To UBound($aOrg) - 1
        $aTemp = StringSplit($aOrg[$i], "", 2)
        For $j = 0 To UBound($aTemp) - 1
            $array[$i][$j] = $aTemp[$j]
        Next
    Next
    _ArrayDisplay($array)
EndFunc   ;==>_Example

[jguinch]

#Include <Array.au3>

$string = "C1 X1 B2"

$aSplit = StringRegExp($string, "([BCJLPX]\d)", 3)

Local $aRes[ UBound($aSplit) ][2]
For $i = 0 To UBound($aSplit) - 1
    $aRes[$i][0] = StringLeft($aSplit[$i], 1)
    $aRes[$i][1] = StringRight($aSplit[$i], 1)
Next
_ArrayDisplay($aRes)