Sign in to follow this  
Followers 0
Michiel

Slider with numbered position indicator

2 posts in this topic

Hi. Borrowing this ASCII graphic from this post (which is basically the same question):

'?do=embed' frameborder='0' data-embedContent>>
 

_____________    <-- slider
| | | | | | |
1 2 3 4 5 6 7

My question is: is there a way to create a slider as above?

This image conveys what I want pretty well, too:

sliderwithticks.jpg?w=595

Share this post


Link to post
Share on other sites



Michiel,

This seems to work quite well for the 3 examples you posted:

#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>

$hGUI = GUICreate("Test", 500, 500)

$iSliderWidth = 400
$iSliderX = 50
$iSliderMax = 200 ; <<<<<<<<<<<<<<<<
$iSliderMin = 0
$iTicInterval = 25 ; <<<<<<<<<<<<<<<
$iLabelPos = Floor(($iSliderWidth - 30) * $iTicInterval / ($iSliderMax - $iSliderMin)) ; subtract 30 from slider wdth to allow for non-used space at each end
$iLabelCount = $iSliderMax / $iTicInterval
$iLabelWidth = 20

$cSlider = GUICtrlCreateSlider($iSliderX, 10, 400, 30, $TBS_AUTOTICKS)
; Set range
_GUICtrlSlider_SetRange($cSlider, 0, $iSliderMax)
; Set tic freq
_GUICtrlSlider_SetTicFreq($cSlider, $iTicInterval)

For $i = 0 To $iLabelCount + 1
    ; Clear overspill flag
    $bOverspill = False
    ; Calculate tic value
    $iLabelValue = $i * $iTicInterval
    ; Check if over max
    If $iLabelValue >= $iSliderMax Then
        $bOverspill = True
        $iLabelValue = $iSliderMax
    EndIf
    ; Create label
    GUICtrlCreateLabel($iLabelValue, $iSliderX + 10 + ($i * $iLabelPos), 45, $iLabelWidth, 15) ; Add 10 to allow for unused space at beginning of slider
    ; check for overspill
    If $bOverspill Then ExitLoop
Next

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
Changing the values in the <<<<<<< lines produces close approximations of your visuals. :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0