_GUICtrlListView_GetItemText not working with variable

[MuffettsMan]

_GUICtrlListView_GetItemText seems to return data when I use a static indices but when i use it from a variable it spits back null....

 

sample code:

(when u select the second row - indice 1 it 'should' report back the value... however console log ends up:

$selectedRow ID: 1

 dynamic rowID: 

 static rowID: Row 1: Col 2

>Exit code: 0    Time: 12.189

 

static rowID is line 63 where i hardcoded 1 instead of using the variable from _GUICtrlListView_GetSelectedIndices

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Example()

Func Example()
    Global $hImage, $hListView

    ; Create GUI
    GUICreate("ListView Add SubItem", 400, 350)

    $selected = GUICtrlCreateButton("Selected", 276, 300, 73, 25)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268, -1, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)



    ; Add columns
    _GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 100)
    _GUICtrlListView_InsertColumn($hListView, 1, "Column 2", 100)
    _GUICtrlListView_InsertColumn($hListView, 2, "Column 3", 100)

    ; Add items

      For $i = 0 To 50
         ; ConsoleWrite("i: " & $i & @CRLF)
          _GUICtrlListView_AddItem($hListView, "Row " & $i & ": Col 1", $i)
          _GUICtrlListView_AddSubItem($hListView, $i, "Row " & $i & ": Col 2", 1, 1)
          _GUICtrlListView_AddSubItem($hListView, $i, "Row " & $i & ": Col 3", 2, 2)
      Next
; ConsoleWrite("i: " & $i & @CRLF)
    ; Loop until the user exits.

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $selected
           getSelected()

        EndSwitch



   sleep(10) ; take it easy on the CPU.
WEnd

 EndFunc   ;==>Example




Func getSelected()
   $selectedRow = _GUICtrlListView_GetSelectedIndices($hListView) ; return the selected row
   ConsoleWrite("$selectedRow ID: " & $selectedRow & @CRLF)

   $rowID = _GUICtrlListView_GetItemText($hListView, $selectedRow, 1)
   ConsoleWrite(" dynamic rowID: " & $rowID & @CRLF)

   $rowID = _GUICtrlListView_GetItemText($hListView, 1, 1)
   ConsoleWrite(" static rowID: " & $rowID & @CRLF)
EndFunc ;==> getSelected

[maniootek]

add this code:
 

$hListView = GUICtrlGetHandle($hListView)

 
after GUICtrlCreateListView() function

[BrewManNH]

Actually if you change the line to this, it will work with the control ID or the variable.

$rowID = _GUICtrlListView_GetItemText($hListView, Number($selectedRow))

The function requires a number, _GUICtrlListView_GetSelectedIndices returns a string containing a number. I'm not sure why the SendMsg function works with the string, but the GUICtrlSendMsg function won't. Maybe it has something to do with the DLLCall function that converts the string to a number.

[MuffettsMan]

thx BrewManNH - I didn't even try that because I always felt autoit was a loosely typed language (that converts a char to int on the fly or doesn't need to be specified) at least never had a problem with it in the past - least I know the workaround now 

ty ty again