_GUICtrlListView_AddItem manipulate record StringRegExp

[rootx]

$text = 'C:\xxx\hh\hhhh\hhh\image.JPG'
$out  = StringRegExp($text,'.*\\(.*)\\',1)

Return the last folder hhh.

I would use this expression in the cycle below.
 

Local $aArray = _FileListToArrayRec("C:\test\app", "*app.exe", $FLTAR_FILES, 1, $FLTAR_SORT,$FLTAR_FULLPATH)

$fileArray = UBound($aArray) -1
    For $y = 1 To $fileArray
        _GUICtrlListView_AddItem($ListView,  StringRegExp($aArray[$y],'.*\\(.*)\\',1), 0)
    Next

 My target is to remove everything from the path, and take only the last folder.

Thanks

[jchd]

Local $aArray = _FileListToArrayRec("C:\test\app", "*app.exe", $FLTAR_FILES, 1, $FLTAR_SORT,$FLTAR_FULLPATH)

$fileArray = UBound($aArray) -1
    For $y = 1 To $fileArray
        _GUICtrlListView_AddItem($ListView,  StringRegExp($aArray[$y],'.*\\(.*)\\',1)[0], 0)
    Next

Should work with recent version (untested).

[mikell]

StringRegExp returns an array and your code needs a string then you also could use StringRegExpReplace

$text = 'C:\xxx\hh\hhhh\hhh\image.JPG'
$out  = StringRegExpReplace($text, '.*\\(.*)\\.*', "$1")
msgbox(0,"", $out)

 

[rootx]

Thanks guys, perfect. One more question, between the two methods which one is more powerful?

[mikell]

I don't understand 'powerful'
Meaning speed, the SRER may be a little slower because of the backreferencing but the difference is anecdotic if the expression is built for this purpose (the SRE could also be modified though) 

$text = 'C:\xxx\hh\hhhh\hhh\image.JPG'

$t1 = TimerInit()
For $i = 1 to 10000
  $out  = StringRegExpReplace($text, '.*\\([^\\]+)\\[^\\]*', "$1")
Next
$r1 = TimerDiff($t1)

Sleep(100)
$t2 = TimerInit()
For $i = 1 to 10000
  $out  = StringRegExp($text, '.*\\(.*)\\', 1)[0]
Next
$r2 = TimerDiff($t2)

Msgbox(0,"", "$out1 = " & $r1 & @crlf & "$out2 = " & $r2)

 

Edited April 29, 2015 by mikell