SevereMessage

Show Password box

2 posts in this topic

#1 ·  Posted (edited)

So, I made a checkbox


 

GLOBAL $PassStart = IniRead("Config.ini","Config","Password","Default Value")

$Input2 = GUICtrlCreateInput("", 40, 64, 249, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))

$Checkbox2 = GUICtrlCreateCheckbox("Show Password", 40, 136, 153, 17)

GUICtrlSetData($Input2,$PassStart)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Checkbox2
            If GUICtrlRead($CheckBox2) = $GUI_CHECKED Then

            Else
            
            EndIf
    EndSwitch
WEnd

and I would like to make it so it shows the hidden password in plaintext, while still keeping the data recieved? I know a nooby way to do this, which would be to I guess make another InputLabel then load $PassStart, but I think that's not a good way to do this, and there must be an easier way?

Edited by SevereMessage

Share this post


Link to post
Share on other sites



SeverMessage,

There certainly is an easier way:

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>

Global $PassStart = IniRead("Config.ini", "Config", "Password", "Default Value")

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("", 10, 10, 200, 20, BitOR($GUI_SS_DEFAULT_INPUT, $ES_PASSWORD))

$cCheck = GUICtrlCreateCheckbox("Show Password", 10, 50, 150, 20)

GUICtrlSetData($cInput, $PassStart)

GUISetState()

;Retrieve the ASCII value of the default password char
$sDefaultPassChar = GUICtrlSendMsg($cInput, $EM_GETPASSWORDCHAR, 0, 0)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCheck

            If GUICtrlRead($cCheck) = $GUI_CHECKED Then
                GUICtrlSendMsg($cInput, $EM_SETPASSWORDCHAR, 0, 0)
                GUICtrlSetData($cCheck, "Show Password")
            Else
                GUICtrlSendMsg($cInput, $EM_SETPASSWORDCHAR, $sDefaultPassChar, 0)
                GUICtrlSetData($cCheck, "Hide Password")
            EndIf

            GUICtrlSetState($cInput, $GUI_FOCUS)
    EndSwitch

WEnd

Please ask if you have any questions.

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now