User input into Variable.

[Tac0s]

Hi!

New to the forums, hopefully you can help.

I am trying to use a gui input as a variable for the rest of the script, but cannot seem to make it work.
We need to get the client to indicate his username, and using that input and declaring it as a variable we can then indicate the path to his userprofile (in order to install some files on their profile - We are running a software installation with admin rights and unfortunately some of the necessary files end up in the Admin account used to run the setup.exe).

So looking at my code below, could you perhaps help to clarify what could be wrong?
Thanks!

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

Const $Username = GUICtrlRead ("")
Const $Profile = "C:\users"

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("title", 347, 317, 379, 128)
$Label1 = GUICtrlCreateLabel("Please Write your  Username:", 24, 136, 300, 65)
$Input1 = GUICtrlCreateInput("", 32, 216, 297, 21)
$Button1 = GUICtrlCreateButton("OK", 128, 248, 81, 33)
$Pic1 = GUICtrlCreatePic("", 8, 0, 332, 108)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
        Exit
        Case $Button1
        GUICtrlRead($Input1)
        If FileExists ($Profile & $Input1) Then
            MsgBox (0, "Info", "Username Exists" , 0, "")
        Else
            MsgBox (0, "Info", "Wrong Username", 0, "")
        EndIf
        If FileExists ($Profile & $Input1) Then
            ExitLoop
        EndIf
    EndSwitch
WEnd

 getlocalusernameAUTOIT.au3

[jguinch]

1/ You have to retrieve the control value with GUICtrlRead

$username = GUICtrlRead($Input1)

2/ The FileExists needs a "\" (or add a "\" to the $Profile value)

If FileExists ($Profile & "\" & $username) ...

3/ You can put the ExitLoop just after the MsgBox and then remove the second FileExits test

Here is a corrected version :

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

Local $Username
Const $Profile = "C:\users"

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("title", 347, 317, 379, 128)
$Label1 = GUICtrlCreateLabel("Please Write your  Username:", 24, 136, 300, 65)
$Input1 = GUICtrlCreateInput("", 32, 216, 297, 21)
$Button1 = GUICtrlCreateButton("OK", 128, 248, 81, 33)
$Pic1 = GUICtrlCreatePic("", 8, 0, 332, 108)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
        Exit
        Case $Button1
            $username = GUICtrlRead($Input1)
            If FileExists ($Profile & "\" & $username) Then
                MsgBox (0, "Info", "Username Exists" , 0, "")
                ExitLoop
            Else
                MsgBox (0, "Info", "Wrong Username", 0, "")
            EndIf
    EndSwitch
WEnd

 

[Melba23]

Tac0s,

Welcome to the AutoIt forums.

Look at the changes I made:

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

Const $Username = GUICtrlRead ("")
Const $Profile = "C:\users\"                                ; Add a "\" here

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("title", 347, 317, 379, 128)
$Label1 = GUICtrlCreateLabel("Please Write your  Username:", 24, 136, 300, 65)
$Input1 = GUICtrlCreateInput("", 32, 216, 297, 21)
$Button1 = GUICtrlCreateButton("OK", 128, 248, 81, 33)
$Pic1 = GUICtrlCreatePic("", 8, 0, 332, 108)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
    Switch $nMsg

        Case $GUI_EVENT_CLOSE
        Exit
        Case $Button1
        $sUsername = GUICtrlRead($Input1)                   ; You need to put the content into a variable...
        If FileExists ($Profile & $sUsername) Then          ; ...which you then use here
            MsgBox (0, "Info", "Username Exists" , 0, "")
            ExitLoop                                        ; And you can put this here rather then ask the same queston again
        Else
            MsgBox (0, "Info", "Wrong Username", 0, "")
        EndIf



    EndSwitch

WEnd

Please ask if you have any questions.

M23

Edit: Getting slow in my old age!

Edited August 14, 2015 by Melba23