hidden values in dropdowns

[DrPickles]

in PHP you can show one thing and have a different value hidden

<select id="animal" name="animal">

<option value="0">--Select Animal--</option>

<option value="1">Cat</option>

<option value="2">Dog</option>

<option value="3">Cow</option>

</select>

 

this is great when working across databases because you can use unique identifiers.

so if I say dog I can now use the value of 2 to look for directly related material in sqllite.

 

does this exist in autoit?

[JLogan3o13]

Are you talking about a GUI you create? Something like this?

#include <GUIConstantsEx.au3>

    Local $x

    $hGUI = GUICreate("Test", 300, 300)
    $hList = GUICtrlCreateCombo("Select Animal", 10, 10, 280, 40)
        GUICtrlSetData(-1, "Cat|Dog|Cow")

    $btnGo = GUICtrlCreateButton("Go", 10, 200, 40, 30)

        GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
            Case $btnGo
                Switch GUICtrlRead($hList)
                    Case "Cat"
                        $x = 1
                    Case "Dog"
                        $x = 2
                    Case "Cow"
                        $x = 3
                EndSwitch
                MsgBox(0, "", $x)
        EndSwitch
    WEnd

 

[Melba23]

DrPickles,

Or something like this perhaps:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3>

Local $aArray[3][2] = [["Cat", 1], ["Dog", 2], ["Cow", 3]]
$sData = ""
For $i = 0 To UBound($aArray) - 1
    $sData &= "|" & $aArray[$i][0]
Next

$hGUI = GUICreate("Test", 500, 500)

$cCombo = GUICtrlCreateCombo("", 10, 10, 280, 20)
GUICtrlSetData($cCombo, "Cat|Dog|Cow")

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo

            $sChoice = GUICtrlRead($cCombo)
            $iIndex = _ArraySearch($aArray, $sChoice)
            If Not @error Then
                MsgBox($MB_SYSTEMMODAL, "Index", $aArray[$iIndex][1])
            EndIf

    EndSwitch
WEnd

Many ways to skin this particular cat.

M23