DarkBanana

Resize Child GUI

2 posts in this topic

Hello,

I'm looking for a way to scale a child gui according to a treeview.

Example:

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
#include <WinApi.au3>

    $Gui = GUICreate("TreeView Find Item", 400, 340,-1,-1,$WS_SIZEBOX)

    $idTreeView = GUICtrlCreateTreeView(20, 20, 100, 260)
    $Child_GUI = GUICreate("as",200,260,150,20,BitOR($WS_POPUP, $WS_BORDER))
    GUISetBkColor(0xFFFFFF,$Child_GUI)
    _WinAPI_SetParent($Child_GUI, $GUI)

    GUISetState(@SW_SHOW,$GUI)
    GUISetState(@SW_SHOW,$Child_GUI)
    For $x = 0 To 3
        GUICtrlCreateTreeViewItem($x,$idTreeView)
    Next




    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()

I want to have a nice alignment between the child gui and the treeview.

But if I resize the whole GUI only the treeview changes. How do I get the child gui to scale together with the treeview?

 

Thanks in advance.

 

Share this post


Link to post
Share on other sites



DarkBanana,

I usually create a label (make it transparent so you cannot see it in the real case) and then resize the child GUI to fit when the GUI is resized:

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
#include <WinApi.au3>

$Gui = GUICreate("TreeView Find Item", 400, 340, -1, -1, $WS_SIZEBOX)

$idLabel = GUICtrlCreateLabel("", 150, 20, 200, 260) ; Label which will adjust with the GUI
GUICtrlSetBkColor($idLabel, 0xFFCCCC)

$idTreeView = GUICtrlCreateTreeView(20, 20, 100, 260)

$Child_GUI = GUICreate("as", 200, 260, 150, 20, BitOR($WS_POPUP, $WS_BORDER))
GUISetBkColor(0xFFFFFF, $Child_GUI)
_WinAPI_SetParent($Child_GUI, $Gui)

GUISetState(@SW_SHOW, $Gui)
GUISetState(@SW_SHOW, $Child_GUI)

For $x = 0 To 3
    GUICtrlCreateTreeViewItem($x, $idTreeView)
Next

GUIRegisterMsg($WM_SIZE, "_WM_SIZE")


Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()


Func _WM_SIZE($hWnd, $iMsg, $wParam, $lParam)

    ; Get label posiition and size and adjust child GUI to fit
    $aPos = ControlGetPos($Gui, "", $idLabel)
    WinMove($Child_GUI, "", $aPos[0], $aPos[1], $aPos[2], $aPos[3])

EndFunc

Please ask if you have any questions.

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now