TreeView - Check whether Icon is set (and which one?)

[DarkBanana]

I'm looking for a function like : _GuiCtrlTreeView_GetIcon()

I need to find out whether my treeview icon has an icon or not. 

How do I do that?

 

[Melba23]

DarkBanana,

You will need to use _GUICtrlTreeView_GetImageIndex - this example shows you how:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $ahItem[10], $hImage, $hRandomImage, $hRandomItem, $idTreeView

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    GUICreate("TreeView Get Image Index", 400, 300)

    ; Create TreeView

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    ; Create ImageList

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    ; Fill treView

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 9
        If Mod($x, 2) Then
            ; Create item with icon
            $hRandomImage = Random(0, 5, 1)
            $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] Icon Item", $x + 1), $hRandomImage, $hRandomImage)
        Else
            ; Create item without icon
            $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] No Icon Item", $x + 1), 6, 6) ; Value above image list max index
        EndIf

    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    ; Read icon states
    For $iItem = 0 To 9
        $iImageIndex = _GUICtrlTreeView_GetImageIndex($idTreeView, $ahItem[$iItem])
        $vIcon = ( ($iImageIndex = 6) ? ("Empty") : ($iImageIndex) )
        ConsoleWrite( StringFormat("Item %d Image Index: %s", $iItem, $vIcon) & @CRLF)
    Next

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

All clear?

M23