Array Loop while deleting elements

[ZipleR]

Every time I need loop through an array and remove elements I run into issues.. 

Can anyone help me understand a good way to loop through an array, remove elements and NOT crash due to

==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:

Here is some sample code that I have to show you the type of loop I am talking about.

Local $bResult[1], $aResult[6] = ["5","Item1","Item2","Item3","Item4","*Item5"]


;Loop through an array and remove any element starting with "*"
For $x = 1 to $aResult[0] ;starting $x at 1 to skip the Array Size row [0].

    If StringLeft($aResult[$x],1) = "*" then ; This will test if item $x in the array starts with "*"
        $bResult[0] = _ArrayAdd($bResult,$aResult[$x]) ;if it does, Add it to a second array and store the Array size in $bResult[0]
        $aResult[0] = _ArrayDelete($aResult,$x);remove the element from the array and store the new array size in $aResult[0]
        $x -= 1 ;This will lower $x by one so the next time through the element that moved up will be tested
    EndIf



Next

_ArrayDisplay($aResult, "Source") ;Display what was in the source array
_ArrayDisplay($bResult, "Destination") ;Display what was moved to the destination array.

Any advice would be much appreciated.

Thank you!

[BrewManNH]

You need to loop through your array in reverse, otherwise you'll end up deleting the wrong elements, or your loop will run past the end of the array.

#include <Array.au3>
Local $bResult[1], $aResult[6] = ["5", "Item1", "*Item2", "Item3", "Item4", "*Item5"]


;Loop through an array and remove any element starting with "*"
For $x = $aResult[0] To 1 Step - 1 ; < << <<< Loop through the array in reverse
    If StringLeft($aResult[$x], 1) = "*" Then ; This will test if item $x in the array starts with "*"
        $bResult[0] = _ArrayAdd($bResult, $aResult[$x]) ; if it does, Add it to a second array and store the Array size in $bResult[0]
        $aResult[0] = _ArrayDelete($aResult, $x); remove the element from the array and store the new array size in $aResult[0]
    EndIf
Next

_ArrayDisplay($aResult, "Source") ;Display what was in the source array
_ArrayDisplay($bResult, "Destination") ;Display what was moved to the destination array.

 

[ZipleR]

So glad I asked..  That is WAY easier than I was making it...

Thank you!