GUICtrlRead returns a number from a listview instead of the text

[PetterBomban 0]

Hi folks.

I'm trying to automate blocking of students network access by bulk, instead of blocking each and every class manually.

So far so good, I have managed to make it work. Now I have to create a GUI for it, so that the other guys at the office can use it.

I'm having some trouble though. Instead of outputting the text in my listview, it outputs a number, no matter what I select.

Here are some screenshots to better explain:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>

mainGUI()

Func mainGUI()

    Local $msg

    Local $GUI = GUICreate("Menu", 1000, 850)
    
    Local $button1 = GUICtrlCreateButton("Button 1", 5, 30, 100, 25)
    
    Local $listOfGroups = GUICtrlCreateListView("", 5, 100, 180, 500, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL, $WS_VSCROLL, $LVS_SHOWSELALWAYS))
    Local $listOfGroupsItems = ["test", "testd", "asdasd", "asdasdasdasdasd"]

    For $groupItem in $listOfGroupsItems
        GUICtrlCreateListViewItem($groupItem, $listOfGroups)
    Next
    
    GUISetState()

    While 1
        
        $msg = GUIGetMsg()
        
        Select
            
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
                
            Case $msg = $button1
                $testRead = GUICtrlRead($listOfGroups)
                MsgBox(0, 'Button 1', $testRead)
    
        EndSelect
        
    WEnd
    
EndFunc ;==> mainGUI()

 

 

 

 

[Jos 1,038]

These are the handles returned by the GUICtrlCreateListViewItem() statement which you aren't capturing.

Jos

[PetterBomban 0]

These are the handles returned by the GUICtrlCreateListViewItem() statement which you aren't capturing.

Jos

Could you give me an example of how it is done?

 

Edit: Found out how: 

GUICtrlRead(GUICtrlRead($listview)).

But now I am having another problem. How do I print out all the values selected? Currently, only one value at a time will show up.

Any pointers?

Edited December 11, 2015 by PetterBomban

[BrewManNH 971]

Use _GUICtrlListView_GetSelectedIndices  and loop through the array to find out what the text/information is from those selected indices.

[PetterBomban 0]

I think I solved it.

$items = _GUICtrlListView_GetSelectedIndices($listOfGroups, True)
For $item in $items
    $rowName = _GUICtrlListView_GetItemText($listOfGroups, Number($item), 0)
    ConsoleWrite($rowName)
Next

 

[BrewManNH 971]

I wouldn't use a For In loop with the array returned by the first function, the first element of the array is going to be the count of selected items in the listview. This is going to give you wrong results. You should use a regular For/Next loop instead and start the loop at 1 instead of zero.

[PetterBomban 0]

I wouldn't use a For In loop with the array returned by the first function, the first element of the array is going to be the count of selected items in the listview. This is going to give you wrong results. You should use a regular For/Next loop instead and start the loop at 1 instead of zero.

Thanks a ton! It's as you said, the For..In loop made weird things happen.

$items = _GUICtrlListView_GetSelectedIndices($listOfGroups, True)
$itemsNum = UBound($items)

For $i = 1 To $itemsNum - 1
    $rowName = _GUICtrlListView_GetItemText($listOfGroups, Number($items[$i]), 0)
    ConsoleWrite("  -  ")
    ConsoleWrite($rowName)
Next

Edited December 16, 2015 by PetterBomban